Kann man Strg+C deaktivieren?

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Hirn
mir ist nicht ganz klar von wo was wohin kopiert wird. Aus deinem zu schützenden Blatt in ein anderes ?
Das verhindert die Prozedur die ich die als erstes beschrieben hab.

Oder von einem anderen Blatt in dein zu schützendes ? Dafür lautet die Prozedur wie folgt:

Option Explicit
Private Sub Worksheet_Activate()
Application.CutCopyMode = False
End Sub

Oder innerhalb des zu schützenden Blattes ? Dafür lautet die Prozedur wie folgt:

Option Explicit
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Application.CutCopyMode = False
End Sub

Wenn du alle drei Möglichkeiten ausschließen willst, musst du alle drei Prozeduren in das Klassenmodul des zu schützenden Arbeitsblattes eingeben. Die Anweisung "Option Explicit" darf aber nur einmal am Anfang des Moduls stehen. Zum öffnen des Klassenmoduls einfach mit der rechten Maustaste auf den Tabellenreiter (das ist das, wo der Name der Tabelle steht) und "Code anzeigen" anklicken. Dann Code eingeben, VBA-Editor schließen (Kreuz ganz oben rechts) speichern, fertig.

Gruß
Nepumuk

Hallo Hirn
hier die benötigten Makros:

Option Explicit
'Ihnen stehen damit die Prozeduren
'"procKopierenAusschneidenAus" sowie
'"procKopierenAusschneidenEin" zum Deaktivieren bzw.
'Einschalten der Kopier-Funktionen zur Verfuegung, die Sie
'nun noch ueber entsprechende Ereignisprozeduren automatisch
'aufrufen muessen. In der Regel bietet es sich an, die
'Schutzfunktion einzuschalten, wenn die Arbeitsmappe
'geoeffnet wird und den alten Zustand beim Schliessen der
'Datei wiederherzustellen. Verwenden Sie dazu die folgenden
'Prozeduren im Modul "Diese Arbeitsmappe":

Sub procKopierenAusschneidenAus()
'Tastenkombinationen deaktivieren
Application.OnKey "^x", ""
Application.OnKey "^c", ""
Application.OnKey "^v", ""
Application.OnKey "+{DEL}", ""
Application.OnKey "+{INSERT}", ""

'Drag & Drop ausschalten
Application.CellDragAndDrop = False

' Schaltflaechen deaktivieren
procControlEnableDisable 21, False ' Ausschneiden
procControlEnableDisable 19, False 'Kopieren
procControlEnableDisable 22, False 'Einfuegen
procControlEnableDisable 755, False 'Inhalte einfuegen

End Sub

Sub procKopierenAusschneidenEin()
'Tastenkombinationen einschalten
Application.OnKey "^x"
Application.OnKey "^c"
Application.OnKey "^v"
Application.OnKey "+{DEL}"
Application.OnKey "+{INSERT}"

'Drag & Drop wieder erlauben
Application.CellDragAndDrop = True

' Schaltflaechen aktivieren
procControlEnableDisable 21, True ' Ausschneiden
procControlEnableDisable 19, True 'Kopieren
procControlEnableDisable 22, True 'Einfuegen
procControlEnableDisable 755, True 'Inhalte einfuegen

End Sub

Sub procControlEnableDisable(intId As Integer, _
bolStatus As Boolean)

Dim cmbSuche As CommandBar
Dim cmbcSteuerelement As CommandBarControl

For Each cmbSuche In Application.CommandBars
Set cmbcSteuerelement = _
cmbSuche.FindControl(Id:=intId, recursive:=True)

If Not cmbcSteuerelement Is Nothing Then
cmbcSteuerelement.Enabled = bolStatus
End If
Next

End Sub

UND IN DIESE ARBEITSMAPPE:

Option Explicit

Private Sub Workbook_Open()
procKopierenAusschneidenAus
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
procKopierenAusschneidenEin
End Sub

Ich hoffe, das hilft die weiter

Gruß Dieter

Beliebteste Forumthreads (12 Monate)

20 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

20
Beiträge zum Forumthread

Beiträge zu diesem Forumthread