Gibt es eine Möglichkeit, die Excel nach ablauf einer bestimmten Zeit in der excel nicht benutzt wurde, veranlasst automatisch zu speichern und zu beenden?
Besten Dank für eure Hilfe!
Sascha
Gibt es eine Möglichkeit, die Excel nach ablauf einer bestimmten Zeit in der excel nicht benutzt wurde, veranlasst automatisch zu speichern und zu beenden?
Besten Dank für eure Hilfe!
Sascha
Also es ist eine Materialbestellliste, auf die von mehreren Workstations im Netzwerk zugegriffen wird... Und leider gibts leute die diese liste dann icht mehr schliessen.. Es sind also nur Eingaben... Und sobald zbs. 1 Minute nichts mehr verändert wurde, sprich nichts geschrieben, sollte Excel speichern und schliessen!
Thanx!
in diese Arbeitsmappe
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Zurücksetzen
End Sub
Private Sub Workbook_Open()
startzeit
End Sub
Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
startzeit
End Sub
in ein Modul
Option Explicit
Dim datA As Date
Sub startzeit()
On Error Resume Next
Application.OnTime EarliestTime:=datA, Procedure:="Schließen", Schedule:=False
datA = Now + CDate("0:08:0")
Application.OnTime datA, "Schließen"
End Sub
Sub Schließen()
ActiveWorkbook.Close True
End Sub
Sub Zurücksetzen()
Application.OnTime EarliestTime:=datA, Procedure:="Schließen", Schedule:=False
End Sub
gruss geri
Mappe speichern --> schliessen --> und neu öffnen
gruss geri
1. In das Klassenmodul "Diese Arbeitsmappe"
Option Explicit
Private Sub Workbook_Open()
einschalten
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
ausschalten
End Sub
2. In das Klassenmodul des Tabellenblattes
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
ausschalten
einschalten
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
ausschalten
einschalten
End Sub
3. In ein normales Modul
Option Explicit
Public beenden As Date
Public Sub einschalten()
beenden = Time + TimeSerial(0, 1, 0)
Application.OnTime beenden, "Ende"
End Sub
Public Sub ausschalten()
On Error Resume Next
Application.OnTime beenden, "Ende", , False
End Sub
Public Sub Ende()
ThisWorkbook.Save
If Workbooks.Count = 1 Then Application.Quit Else ThisWorkbook.Close
End Sub
Am besten ist es die Makros digital zu signieren, dann kommt beim öffnen der Mappe die Abfrage, ob die Makros aktiviert weren sollen, nicht.
Gruß
Nepumuk
Besten Dank für eure überaus grosszügige Hilfe!!
Noch eine Frage.. wie geht das mit der Digitalen Signatur (Sorry, bin halt schon ein Newbie..)? Habe zwar ein Auswahlfenster gefunden, jedoch nichts zum auswählen?!?
Gruss
Sascha
gruss geri
Ich habe jetzt gemerkt, dass Excel schliesst, auch wenn ich noch am schreiben bin! Wird zwar sauber gespeichert, jedoch ist das schon ein wenig umständlich, wenn einem die bestelliste plötzlich vor den augen verschwindet...?!? Lösungen?
Sascha
Etwa 1 Minute hab ich gemessen... aber eben, der stellt ab ob ich noch am schreiben bin oder nicht... :/
Gruss
Vielen Dank! Dein Teil funktioniert tatsächlich einwandfrei!!
Vielen Dank!
Sascha