CommandBarControl - Welcher Button ist gedrückt ?

Liebe Excel Gemeinde,
und schon habe ich das nächste Problem mit den CommandBarControls:
Ich möchte die gleiche Subroutine für mehrere Buttons benutzen (OnACtion = "DieselbeRoutine"). Das klappt auch wunderbar, nur muss ich in der Routine dann feststellen, welcher der Buttons sie angestartet hat. Mein Versuch über die .State Eigenschaft geht leider fehl (Msgbox meldet, dass .State immer gleich 0 sei).
Dim objTargetMonitorBar As CommandBar
Dim objButton As CommandBarControl

Set objTargetMonitorBar = Application.CommandBars("Zielwert Monitor")

For Each objButton In objTargetMonitorBar.Controls
MsgBox objButton.State
Next objButton
Bin dankbar für jede Idee, welche Eigenschaft sonst mir die Information gibt.
CIAO
Michael

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Michael,
da wirst du wohl ein Klassenmodul brauchen:
''In ein Standardmodul
Option Explicit
Option Base 1
Public Const b As Byte = 5 'Anzahl der Button
Public arrButton(b) As New clsMenu
Public Const CBNAME As String = "K.Rola"
Private M As clsMenu
''-------------------------------------------------------------
Sub MenuLeiste_erzeugen()
Dim objCB As CommandBar
On Error Resume Next
CommandBars(CBNAME).Delete
On Error GoTo 0
Set objCB = CommandBars.Add(Name:=CBNAME)
Set M = New clsMenu
M.MenuLeiste
With objCB
.Position = msoBarFloating
.Visible = True

End With
End Sub

''--------------------------------------------------------------
Sub setten()
Dim i As Byte
For i = 1 To b
Set arrButton(i).cmdButton = CommandBars(CBNAME).controls(i)
Next
End Sub

''--------------------------------------------------------------
''In ein Klassenmodul, das zwingend clsMenu heißen muss--------
''
''Klassenmodul: clsMenu
''
''-------------------------------------------------------------
Option Explicit
Public WithEvents cmdButton As CommandBarButton
Sub MenuLeiste()
Dim x As Byte
With CommandBars(CBNAME)
For x = 1 To b
Set cmdButton = .controls.Add(Type:=msoControlButton)
With cmdButton
.Style = msoButtonIconAndCaption
.Caption = "Button" & x
.Width = 100
.FaceId = 29
.Tag = x
.BeginGroup = True
End With
Next
End With
Set cmdButton = Nothing
Call setten
End Sub


Private Sub cmdButton_Click(ByVal Ctrl As Office.CommandBarButton, CancelDefault As Boolean)
''Hier wird das OnAction der Button ausgeführt
MsgBox Ctrl.Caption
End Sub

Ich denke, das Prinzip wird klar.
Gruß K.Rola

Beliebteste Forumthreads (12 Monate)

CommandBarControl - Welcher Button ist gedrückt ?

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread