Hilfe, latein am Ende... wie Speichern?

Hallo allerseits, ich brauche eure Hilfe.
Ich schreibe gerade mein Rechnungsprogramm und bin bis auf meine Buttons auch fertig, aber nun ist Schluß mit lustig!!!
Ich habe folgende 3 Probleme:
1. Ich möchte mit einem Button eine Speicherung unter dem Namen welcher im Feld A1 steht durchführen. (Dort steht die Rechnungsnummer und der Name)
2. Die Rechnungsnummer soll extern in einer Datei abgelegt werden und bei öffnen einer neuen Rechnung wieder aufgerufen werden ( anderes Feld )
3. Wie lege ich eine externe Arbeitsmappe an, bei der ich die Kundendaten speichern und wieder aufrufen kann und zwar ohne sie zu überschreiben ( Art Telefonverzeichniss ? )
Wenn ich die Geschichte hinkriege, kann ich euch das Programm auf Wunsch gerne zumailen. ( danach wird es wohl Verbesserungen hageln )
Ich hoffe Ihr helft mir, da ich mit diesem Programm 2004 meine Rechnungen / Kostenvoranschläge / Abschläge schreiben will und so zurzeit auf dem trockenen sitze.
Gruß Jürgen

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Jürgen,
ich wage mich mal an einen Vorschlag für dein Problem.
1 und 2) Das geht am besten über ein Makro. Hierzu über Menü "Extras -> Makros -> Visual Basic Editor" den VB Editor aufrufen. Dort über das Menü "Einfügen -> Modul" ein neues Makramodul anlegen. Es geht nun ein Fenster auf mit dem Namen "...xls - Modul1 (Code)".
Dann denn nachfolgenden Text einfach in das Modul kopieren.


'Start VBA Code
Option Explicit
'hier den Pfad für die Speicherung der Rechnungsdateien angeben
Private Const SaveDir = "c:\Eigene Dateien\Rechnungen\"
Public Const RegAppName = "Rechnungen"
Public Const RegSection = "Optionen"
Public Const RegKeyNumber = "RENummer"
Public Sub Speichern()
Dim filename    As String
On Error Resume Next
With Application.ActiveSheet
filename = .Range("Dateiname").Value
.SaveAs SaveDir & filename
If Err.Number = 1004 Then
Exit Sub
End If
If Err.Number <> 0 Then
MsgBox "Fehler beim Speichern der Datei '" & filename & _
"' in Verzeichnis '" & SaveDir & "'." & vbNewLine & _
Err.Number & ": " & Err.Description, vbCritical, "Rechnungen"
Exit Sub
End If
'Überprüfen der Rechnungsnummer, ob diese die größte ist und
'somit als letzte RENummer in die Registry eingetragen wird.
CheckRENumber
'Diese Zeile mit einem Kommentarzeichen versehen, falls keine
'Meldung über erfolgreiche Speicherung gewünscht wird
MsgBox "Datei wurde erfolgreich gespeichert", vbInformation, "Rechnungen"
End With
End Sub
Private Sub CheckRENumber()
Dim reNumber        As Long
With Application.ActiveSheet
reNumber = CLng(GetSetting(RegAppName, RegSection, RegKeyNumber, 0))
If CLng(.Range("RENummer").Value) > reNumber Then
SaveSetting RegAppName, RegSection, RegKeyNumber, CLng(.Range("RENummer").Value)
End If
End With
End Sub
'Ende VBA Code

Wichtig!!!
1) Für die einwandfreie Funktion des Makros muss in der Variable "Savedir" der Pfad "c:\Eigene Dateien\Rechnungen\" durch einen gültigen Pfad ersetzt werden.
2) Des weiteren muss in deiner Excel-Arbeitsmappe mit den Rechnungen eine Zelle (z.B. A1) mit dem Namen "Dateiname" existieren. Dort steht dann der Name der zu speichernden Excel-Datei.
3) Es muss eine Zelle mit dem Namen "RENummer" benannt werden. In dieser steht die aktuelle Rechnungsnummer der Rechnung.
4) Des weiteren wird eine Zelle mit den Name "NeuRENummer" benötigt. In dieser wird beim Öffnen die neue Rechnungsnummer geschrieben.
Jetzt kannst du einen Button in deiner Excel-Datei anlegen. Diesem das Makro "Speichern" zuordnen. Das wars!
Das Makro prüft auch beim Speichern, ob die aktuelle Rechnungsnummer größer ist als die bisher gespeicherte Nummer. Wenn ja, dann wird die aktuelle RENummer in die Windows Datenbank (Registry) geschrieben. Somit kann man beim Öffnen einer neuen Rechnungsdatei darauf zugreifen.
Um nun beim Öffnen der Rechnungsdatei-Vorlage die neue Rechnungsnummer zu bekommen, mußt die nachfolgenden Code in die Arbeitsmappe kopieren. Hier mal die genaue Vorgehensweise:
1) Rechnungs-Datei Vorlage mit Excel öffnen
2) Visual Basic Editor öffnen
3) Über Menü "Ansicht -> Projekt-Explorer" das Projektfenster öffnen.
4) Dort den Baum "VBAProject ( aufklappen
5) Dort durch Doppeklick auf "DieseArbeitsmappe" das Modul öffnen
6) In Modulfenster "DieseArbeitsmappe (Code)" den nachfolgenden Code kopieren.
7) Fertig. Nun wird beim jeden Öffnen einer Rechnungsdatei in der Zelle "NeuRENummer" die letzte vergebene Rechnungsnummer PLUS 1 angezeigt. Also somit immer die nächste zu vergebende Rechnungsnummer.


'Start VBA Code
Option Explicit
Private Sub Workbook_Open()
Dim reNumber        As Long
With Application.ActiveSheet
reNumber = CLng(GetSetting(RegAppName, RegSection, RegKeyNumber, 0))
.Range("NeuRENummer").Value = reNumber + 1
End With
End Sub
'Ende VBA Code

Problem 3 verstehe ich nicht ganz. Klar ist, du legst in einer extra Excel-Datei z.B. Kundendaten.xls ein Blatt mit den Kundendaten an. Also z.B. Spalten Firma, Ansprechpartner, Adresse, Telefonnummer. Was ist nun das Problem??? Was soll genau automatisiert werden?

Sub DatenübernahmeTabelle() Dim i As Integer i = Sheets("Tabelle2").Cells(Cells.Rows.Count, 1).End(xlUp).Row + 1 If i < 4 Then i = 4 ' Startzeile für Eintrag ' ZIELBEREICH 'QUELLBEREICH Sheets("Tabelle2").Cells(i, 1) = Sheets("Tabelle1").Cells(9, 1) Sheets("Tabelle2").Cells(i, 2) = Sheets("Tabelle1").Cells(10, 1) Sheets("Tabelle2").Cells(i, 3) = Sheets("Tabelle1").Cells(11, 1) Sheets("Tabelle2").Cells(i, 4) = Sheets("Tabelle1").Cells(4, 2) Sheets("Tabelle2").Cells(i, 6) = Sheets("Tabelle1").Cells(6, 5) Sheets("Tabelle2").Cells(i, 7) = Sheets("Tabelle1").Cells(6, 7) 'cells(zeile,spalte) anpassen End Sub

Beliebteste Forumthreads (12 Monate)

Hilfe, latein am Ende... wie Speichern?

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread