Preise in Preisliste vergleichen

Hallo zusammen,
ich muss die Preise in einem Shop aktualisieren. Dabei habe ich folgendes Szenario:
Ich habe eine Excel-ORIGINAL-Datei in der die Artikelnummer (Spalte A) und der Preis (Spalte B) steht. Nun soll dies mit einer anderen Excel-NEU-Daten, in der auch die Artikelnummer in Spalte A und der Preis in Spalte B steht, verglichen werden.
Da in der Excel-ORIGINAL-Datei aber nur ein Bruchteil der Artikel von der Excel-NEU-Daten vorhanden sind, kann ich es nicht so einfach vergleichen.
Könnte man das mit einem Skript machen? Also lese Artikelnummer in ORIGINAL-DATEI; suche Artikelnummer in NEU-DATEI; hole Preis in der Spalte nebenan und kopiere den Preis in die Preiszelle der ORIGINAL-DATEI.
Mmmmhhhh - geht sowas?
Oder gibt's da ne einfache Funktion und ich bin nur zu doof dazu?
Viele Grüße
Michael

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Michael!
Kopiere diesen Code in ein allgemeines Modul.
Die Namen der Mappen und Tabellenblätter musst
Du natürlich anpassen. Ebenso die Bereiche die
verglichen werden sollen.

Sub PreisAktualisieren()
'Preise anhand von Artikelnummern vergleichen
'und in Original-Datei aktualisieren
'von Josef Ehrensberger
'#############################################
'Namen der Arbeitsmappen, Tabellen anpassen!
'Bereiche in den Tabellenblättern anpassen!
'#############################################
Dim wbkO As Workbook
Dim wbkN As Workbook
Dim wksO As Worksheet
Dim wksN As Worksheet
Dim rngO As Range   'Original
Dim rngN As Range   'Neu
Dim rngV As Range   'Vergleich
Dim rngF As Range   'Fundstelle
Dim intC As Integer
Set wbkO = Workbooks("Mappe2")      'Name der Original-Datei
Set wbkN = Workbooks("Mappe3")      'Name der Neu-Datei
Set wksO = wbkO.Sheets("Tabelle1")  'Name des Tabellenblattes in Original-Datei
Set wksN = wbkN.Sheets("Tabelle1")  'Name des Tabellenblattes in Neu-Datei
Set rngO = wksO.Range("A1:A1000")   'Bereich mit Artikelnumern in Original-Datei
Set rngN = wksN.Range("A1:A500")    'Bereich mit Artikelnumern in Neu-Datei
   For Each rngV In rngO
      If rngV <> "" Then
      Set rngF = rngN.Find(What:=rngV, LookIn:=xlValues, LookAt:=xlWhole)
         If Not rngF Is Nothing Then
         rngV.Offset(0, 1) = rngF.Offset(0, 1)
         intC = intC + 1
         End If
      End If
   Next
MsgBox "+++ Aktualisierung abgeschlossen! +++" & vbLf & vbLf & _
   "Es wurden die Preise von " & intC & " Artikeln aktualisiert!", _
   vbOKOnly + vbInformation, "INFO"
End Sub

Code eingefügt mit Syntaxhighlighter 2.5

Gruß Sepp

Beliebteste Forumthreads (12 Monate)

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread