AW: Danke
03.02.2004 11:03:29
Heinz A. Wankmüller
Hallo Kerstin,
hier mein Code
Sub NotesMail()
Dim Betreff$, Anhang As Variant, Empfänger$, Mailtext$
Betreff = "Lotus-Test"
Anhang = "C:\Daten\Excel\Lösungen\Mailtest.xls"
Empfänger = "heinz.wankmueller@ktn.gv.at"
Mailtext = "Im Anhang wird eine Testdatei übermittelt."
SendNotesMail Betreff, Anhang, Empfänger, Mailtext, False, False
End Sub
Sub SendNotesMail(Subject As String, Attachment As Variant, Recipient As String, BodyText As String, SaveIt As Boolean, Entwurf As Boolean)
'Set up the objects required for Automation into lotus notes
Dim Maildb As Object 'The mail database
Dim UserName As String 'The current users notes name
Dim MailDbName As String 'THe current users notes mail database name
Dim MailDoc As Object 'The mail document itself
Dim AttachME As Object 'The attachment richtextfile object
Dim Session As Object 'The notes session
Dim EmbedObj As Object 'The embedded object (Attachment)
'Dim Attachment As Variant
'Start a session to notes
Set Session = CreateObject("Notes.NotesSession")
'Get the sessions username and then calculate the mail file name
'You may or may not need this as for MailDBname with some systems you
'can pass an empty string
UserName = Session.UserName
MailDbName = Left$(UserName, 1) & Right$(UserName, (Len(UserName) - InStr(1, UserName, " "))) & ".nsf"
'Open the mail database in notes
Set Maildb = Session.GETDATABASE("", MailDbName)
If Maildb.IsOpen = True Then
'Already open for mail
Else
Maildb.OPENMAIL
End If
'Set up the new mail document
Set MailDoc = Maildb.CREATEDOCUMENT
MailDoc.Form = "Memo"
MailDoc.sendto = Recipient
MailDoc.Subject = Subject
MailDoc.body = BodyText
MailDoc.SAVEMESSAGEONSEND = SaveIt
'Set up the embedded object and attachment and attach it
If Attachment <> "" Then
Set AttachME = MailDoc.CREATERICHTEXTITEM(Attachment)
Set EmbedObj = AttachME.EMBEDOBJECT(1454, "", Attachment, "Attachment")
MailDoc.CREATERICHTEXTITEM (Attachment)
End If
'Send the document
If Entwurf Then
Call MailDoc.Save(True, True)
Else
MailDoc.PostedDate = Now() 'Gets the mail to appear in the sent items folder
MailDoc.Send 0, Recipient
End If
'Clean Up
Set Maildb = Nothing
Set MailDoc = Nothing
Set AttachME = Nothing
Set Session = Nothing
Set EmbedObj = Nothing
End Sub
lg
Heinz