Live-Forum - Die aktuellen Beiträge
Datum
Titel
19.04.2024 19:41:34
Bei VBA Ausführung Anzeige einfrieren
19.04.2024 17:05:40
Zählen von Zeilen, in denen in bestimmten Bereich Daten sind
19.04.2024 16:34:52
gemeinsamer Filter über drei Spalten
19.04.2024 15:39:42
Exceltabelle daten per combobox zu word Datei
Du findest keine passende Antwort auf Deine Frage?
Stelle Deine Frage in unserem Live-Forum
Anzeige
Archiv - Navigation
408to412
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
408to412
408to412
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Anzahl der enthaltenen Werte

Anzahl der enthaltenen Werte
Nico
Hi,
ich habe eine Tabelle in der Zahlen stehen:
A2 bis A4883
Stehen unterschiedliche, aber auch teilweise gleiche Maschinennummern.
Ich möchte gerne berechnen lassen, wieviel unterschiedliche Maschinennummern in meiner Tabelle stehen.
Mit: =anzahl(A2:A4883) komme ich nicht viel weiter.
Könnt ihr mir helfen?
Mfg
Nico Ritter

5
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Benutzer
Anzeige
AW: Anzahl der enthaltenen Werte
ingoG
Hallo Nico,
hier wieder meine lieblings-Matrix-Formel ;-)
=summe(1/zählenwenn(a2:a4883;a2:a4883)) (Eingabe abschließen mit Strg-Shift-Enter)
siehe auch www.excelformeln.de
Gruß Ingo
PS eine Rückmeldung wäre nett...
AW: Anzahl der enthaltenen Werte
Nico
Vielen Dank
funtkioniert einwandfrei
Danke für die Rückmeldung oT
ingoG
.
AW: Anzahl der enthaltenen Werte
Mac4
Hallo Nico,
mit folgender Matrixformel gehts:
{=SUMME(WENN(A2:A4883="";0;1/ZÄHLENWENN(A2:A4883;A2:A4883)))}
Die Eingabe der Formel mit Strg+Shift+Return abschließen, die geschweiften Klammern werden dann automatisch erzeugt!
Marc
www.excelformeln.de/formeln.html?welcher=42
Günther
Hi Nico,
schau mal unter
http://www.excelformeln.de/formeln.html?welcher=42
dort steht:
1a) ohne Leerzellen:
{=SUMME(1/ZÄHLENWENN($A$1:$A100;$A$1:$A100))}
1b) mit Leerzellen:
{=SUMME(WENN(A1:A100="";0;1/ZÄHLENWENN(A1:A100;A1:A100)))}
funktionieren auch für mehrere Spalten (Bereich z.B.: A1:D100)
2)
{=SUMME((VERGLEICH(A1:A100&"";A1:A100&"";0)=ZEILE(1:100))*1)-1}
(nur eine Spalte)
3) Wenn es sich nur um Zahlen und nicht um Text handelt, geht es auch ohne Array:
=SUMME((HÄUFIGKEIT(A:A;A:A)&gt0)*1)
Diese Formel ist (da kein Array) sehr schnell und akzeptiert komplette Spalten (A:D).
4) Ergänzung 02.07.2003
Obige Formeln unterscheiden nicht Groß- und Kleinschreibung und die Zeichen * ? ~ können zu falschen Ergebnissen führen.
{=SUMME(1/MMULT(IDENTISCH(A1:A100;MTRANS(A1:A100))*1;ZEILE(1:100)/ZEILE(1:100)))-1}
hebt diese Einschränkungen auf.
Erläuterung
Zu 1a) und 1b)
Von jedem Eintrag wird der Kehrwert seiner Häufigkeit im Bereich addiert.
Bei folgenden Einträgen (zur Verdeutlichung ein extremeres Beispiel als oben)
{1;2;3;3;5;5;5;5}
ergibt sich für jede einzelne Zahl eine Häufigkeit von
{1;1;2;2;4;4;4;4}
der jeweilige Kehrwert beträgt dann
{1;1;0,5;0,5;0,25;0,25;0,25;0,25}
ergibt in Summe: 4
Gruß
Günther
Anmerkung: Formeln mit geschweifter Klammern am Anfang und am Ende sind ARRAY-Formeln. Die geschweifte Klammer nicht mit eingeben, sondern die Formeleingabe abschließen mit Strg+Umsch+Enter
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Jetzt das Excel-Portal bewerten: Deine Stimme zählt!

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige