Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
504to508
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
504to508
504to508
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Druckersymbol deaktivieren

Druckersymbol deaktivieren
22.10.2004 21:30:36
Micha
Hallo!
ich möchte das Drucken mit dem Standard-Druckersymbol verhindern. Das geht ganz gut:
Application.CommandBars("Standard").Controls.Item("Drucken (Canon i865)").Enabled = False
..aber nur solange der selbe Drucker der Standard-Drucker ist. Wie läßt sich das Problem lösen?
Danke Micha

4
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Druckersymbol deaktivieren
22.10.2004 21:46:03
Nepumuk
Hallo Micha,
du msst einfach nach der ID - Nummer suchen:


Public Sub test()
    Dim myCommandBarControl  As CommandBarControl
    Set myCommandBarControl = Application.CommandBars("Standard").FindControl(ID:=2521, Recursive:=True)
    If Not myCommandBarControl Is Nothing Then myCommandBarControl.Enabled = False
    Set myCommandBarControl = Nothing
End Sub


Folgendes Makro listet dir sämtliche ID's in einer Tabelle auf:


Option Explicit
Public Sub create_Id_list()
    Dim myCommandBarControl As CommandBarControl, myCommandBar As CommandBar
    Dim intColumn As Integer, intCount As Integer, lngRow As Long, intCbCount As Integer
    Application.ScreenUpdating = False
    lngRow = 1
    Cells.Clear
    For Each myCommandBar In Application.CommandBars
        intCbCount = intCbCount + 1
        Cells(lngRow, 1) = myCommandBar.Name
        Cells(lngRow, 2) = myCommandBar.NameLocal
        With Cells(lngRow, 3)
            .Value = intCbCount
            .Font.Bold = True
        End With
        For intCount = 1 To myCommandBar.Controls.Count
            With myCommandBar.Controls(intCount)
                 Cells(lngRow + intCount, 1) = .ID
                 Cells(lngRow + intCount, 2) = .Caption
            End With
        Next intCount
        lngRow = lngRow + intCount + 1
    Next
    On Error Resume Next
    For lngRow = 2 To Cells(65536, 1).End(xlUp).Row
        If IsNumeric(Cells(lngRow, 1)) And Trim(Cells(lngRow, 1)) <> "" Then
            intColumn = 3
            For Each myCommandBarControl In Application.CommandBars(Cells(Cells(lngRow, 1).End(xlUp).Row, 1).Value).Controls(Cells(lngRow, 2).Value).Controls
                If Err.Number <> 0 Then GoTo nextone
                With myCommandBarControl
                    Cells(lngRow, intColumn) = .ID
                    Cells(lngRow, intColumn + 1) = .Caption
                End With
                intColumn = intColumn + 2
            Next
        End If
nextone:
    Err.Clear
    Next
    Columns.AutoFit
    Application.ScreenUpdating = True
End Sub


Gruß
Nepumuk
Anzeige
AW: Druckersymbol deaktivieren
22.10.2004 23:04:12
Micha
Yo, danke - funzt toll. Aber eine kurze Erläuterung noch... ist die ID in allen Excel-Versionen gleich, sprich wird das Symbol auch auf anderen Rechner ausgeblendet?
Micha
AW: Druckersymbol deaktivieren
22.10.2004 23:28:57
Nepumuk
Hallo Micha,
so weit ich vergleichen kann, sind sie in 97/2000/XP/2003 identisch.
Gruß
Nepumuk
AW: Druckersymbol deaktivieren
23.10.2004 00:03:12
Micha
Alles klar.. und ich dachte immer, die unterscheiden sich und hab sie darum nicht verwendet. Wieder etwas schlauer ;o)
Nochmal vielen Dank, Du hast mir sehr geholfen.
Micha

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige