AW: Nächste leere Zeile suchen und ausfüllen
04.07.2005 15:35:47
Dieter
Hi Regnar
hier hast Du was zur Auswahl:
Function LetzteZeile _
(objSheet As Worksheet, _
strStartCell As String) As Range 'fuer die letzte Zeile eines zusammenhaengenden Bereichs:
Dim objRange As Range
Dim lngLastRow As Long
Dim lngLastCol As Long
Set objRange = objSheet _
.Range(strStartCell).CurrentRegion
lngLastRow = objRange.Row + _
objRange.Rows.count - 1
lngLastCol = objRange.Column + _
objRange.Columns.count - 1
With objSheet
Set LetzteZeile = .Range _
(.Cells(lngLastRow, objRange.Column), _
.Cells(lngLastRow, lngLastCol))
End With
End Function
Function LetzteSpalte _
(objSheet As Worksheet, _
strStartCell As String) As Range 'fuer die letzte Spalte eines zusammenhaengenden Bereichs:
Dim objRange As Range
Dim lngLastCol As Long
Dim lngLastRow As Long
Set objRange = objSheet _
.Range(strStartCell).CurrentRegion
lngLastCol = objRange.Column + _
objRange.Columns.count - 1
lngLastRow = objRange.Row + _
objRange.Rows.count - 1
With objSheet
Set LetzteSpalte = .Range _
(.Cells(objRange.Row, lngLastCol), _
.Cells(lngLastRow, lngLastCol))
End With
End Function
Function AbsLetzteZeile _
(objSheet As Worksheet) As Range 'fuer die letzte benutzte Zeile eines Tabellenblatts:
Dim objLastCell As Range
Dim lngLastRow As Long
Set objLastCell = objSheet _
.Cells.SpecialCells(xlCellTypeLastCell)
lngLastRow = objLastCell.Row
Set AbsLetzteZeile = objSheet _
.Rows(lngLastRow).EntireRow
End Function
Function AbsLetzteSpalte _
(objSheet As Worksheet) As Range 'fuer die letzte benutzte Spalte eines Tabellenblatts:
Dim objLastCell As Range
Dim lngLastCol As Long
Set objLastCell = objSheet _
.Cells.SpecialCells(xlCellTypeLastCell)
lngLastCol = objLastCell.Column
Set AbsLetzteSpalte = objSheet _
.Columns(lngLastCol).EntireColumn
End Function
'z.B.LetzteZeile(ActiveSheet, "A3").Offset(1, 0).Select
oder auch noch:
Sub letzteZelle()
Dim lR
lR = Worksheets("Tabelle1").Cells(Rows.count, 1).End(xlUp).Row
MsgBox lR
End Sub
Ich hoffe, Du hast genügend Auswahlmöglichkeit
Gruss Dieter