Live-Forum - Die aktuellen Beiträge
Datum
Titel
29.03.2024 13:14:12
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
640to644
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
640to644
640to644
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Makros und VBA löschen

Makros und VBA löschen
24.07.2005 11:35:23
Erich
Hallo...
Ich möchte eine Datei in der mehrere UF und Code sind,
einmal in einen Ordner z.B. "Original" und als Copy
in einen Ordner z.B. "Copy, speichern.
In den Ordner Copy soll die Datei Ohne UF und Code
abgespeichert werden.
Frage, ist so etwas überhaupt machbar.
Gruss Erich

5
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Makros und VBA löschen
24.07.2005 11:44:25
Josef
Hallo Erich!
Das geht so!
Option Explicit

Public Sub Code_loeschen()
    'Gesamten Code und Module löschen
    'von K.Rola
    Dim myVBComponents As Object
    If ActiveWorkbook.Name = ThisWorkbook.Name Then Exit Sub
    'sicherheits-check um nicht sich selbst zu löschen
    With ActiveWorkbook.VBProject
        For Each myVBComponents In .VBComponents
            Select Case myVBComponents.Type
                Case 1, 2, 3
                    .VBComponents.Remove .VBComponents(myVBComponents.Name)
                Case 100
                    With myVBComponents.CodeModule
                        .DeleteLines 1, .CountOfLines
                    End With
            End Select
        Next
    End With
End Sub


Gruß Sepp
P.S.: Rückmeldung nicht vergessen!


Anzeige
AW: Makros und VBA löschen
24.07.2005 11:55:48
Erich
Hallo Josef
Erstmal vielen Dank für die superschnelle Antwort.
So gut bin ich nun auch noch nicht.
Wo Schreibe ich den Code rein und muss das Original
erst gespeichert werden und dann die Copy mit SaveCopyAs?
Verlange ein bißchen viel aber hoffe auf Hilfe.
Gruss Erich
AW: Makros und VBA löschen
24.07.2005 12:34:12
Josef
Hallo Erich!
Kopiere diesen Code in ein allgemeines Modul der Originaldatei.
Den Pfad und den Namen der Kopie musst du anpassen.
Option Explicit

Sub Copy_Ohne_Code()
    Dim objWB As Workbook
    Dim strFile As String
    
    On Error GoTo errorExit
    Application.ScreenUpdating = False
    
    strFile = "F:\Temp\copy.xls" 'Pfad und Name der Kopie
    
    ThisWorkbook.SaveCopyAs (strFile)
    
    Set objWB = Workbooks.Open(strFile)
    
    Code_loeschen objWB
    
    objWB.Close True
    
    errorExit:
    Application.ScreenUpdating = True
End Sub


Private Sub Code_loeschen(mappe As Workbook)
    Dim myVBComponents As Object
    
    If mappe.Name = ThisWorkbook.Name Then Exit Sub
    'sicherheits-check um nicht sich selbst zu löschen
    With mappe.VBProject
        For Each myVBComponents In .VBComponents
            Select Case myVBComponents.Type
                Case 1, 2, 3
                    .VBComponents.Remove .VBComponents(myVBComponents.Name)
                Case 100
                    With myVBComponents.CodeModule
                        .DeleteLines 1, .CountOfLines
                    End With
            End Select
        Next
    End With
End Sub


Gruß Sepp
P.S.: Rückmeldung nicht vergessen!


Anzeige
AW: Makros und VBA löschen
24.07.2005 12:48:37
Erich
Hallo Sepp
Vielen Dank für die Antwort.
Werde es anpassen und bin sicher es klappt.
Wenn ich Probleme bekomme werde ich mich wieder melden.
Nochmals Danke
Gruss Erich
AW: Makros und VBA löschen
24.07.2005 11:45:17
Matthias
Hallo Erich,
wenn die Tabellenblätter keinen Code enthalten, dann z.B: so:

Sub kopieren()
Dim b As Integer, i As Integer, WB As Workbook
i = ThisWorkbook.Sheets.Count
ThisWorkbook.Sheets(1).Copy
Set WB = ActiveWorkbook
For b = 2 To i
ThisWorkbook.Sheets(b).Copy After:=WB.Sheets(WB.Sheets.Count)
Next b
With ActiveWorkbook
.SaveAs Filename:="C:\Kopie\" & ThisWorkbook.Name
.Close
End With
End Sub

Gruß Matthias
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige