allgemeine Laufvariable für While-Schleife?

hi@all!
ich habe eine klasse clsAnalysis mit einem dynamischen array. das hinzufügen eines strings zu diesem array funzt schon. allerdings ist das auslesen noch nicht so ganz wie von mir gewünscht. es soll mit einer konstruktion
While Analysis.getLogfiles() ""
'Tu etwas mit dem aktuellen Element
Wend
ausgelesen werden. hier der code von getLogfiles():
Public


Function GetLogfiles() As String
myI = myI + 1
If myI <= UBound(myLogfiles) Then
myCurrLogfile = myLogfiles(myI)     'das hier ist schrott!
GetLogfiles = myLogfiles(myI)
Else
GetLogfiles = ""
End If
If myI > UBound(myLogfiles) Then
myI = -1
End If
End Function

wie ihr sehen könnt, speichere ich den aktuellen wert des array-elements in einer variablen "myCurrLogfile", auf die mittels Analysis.currLogfile zugegriffen werden kann. also so:
While Analysis.getLogfiles() ""
'Tu etwas mit Analysis.currLogfile
Wend
das ist allerdings ein wüstes unprofessionelles gebastel. gibt es nicht so etwas wie eine globale laufvariable, die standardmäßig für solche schleifen verwendet wird? beispielsweise in perl gibt es so etwas:
foreach(@array) {
//Tu etwas mit $_
}
gibt es eine vergleichbare variable in vba? wenn ja, kann man sie so einfach definieren?
vielen dank für eure hilfe!
mfg
mario

Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Datum

Anwender

Hi Mario,
benutze an Stelle eines Arrays eine Collection. Mal ein ganz doofes Beispiel:
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Private objTiere As clsTiere

Public Sub test()
    Dim varItem As Variant
    Dim intIndex As Integer
    Set objTiere = New clsTiere
    With objTiere.Tiere
        .Add "Dackel", "Hund"
        .Add "Tieger", "Katze"
        .Add "Maus", "Nagetier"
        .Add "Amsel", "Vogel"
    End With
    MsgBox objTiere.Tiere("Hund")
    MsgBox objTiere.Tiere("Vogel")
    For Each varItem In objTiere.Tiere
        MsgBox varItem
    Next
    With objTiere.Tiere
        For intIndex = 1 To .Count
            MsgBox .Item(intIndex)
        Next
    End With
    Set objTiere = Nothing
End Sub

' **********************************************************************
' Modul: clsTiere Typ: Klassenmodul
' **********************************************************************

Option Explicit

Private mcolTiere As Collection

Public Property Get Tiere() As Collection
    Set Tiere = mcolTiere
End Property

Private Sub Class_Initialize()
    Set mcolTiere = New Collection
End Sub

Private Sub Class_Terminate()
    Set mcolTiere = Nothing
End Sub

Gruß
Nepumuk
Excel & VBA Beispiele

Beliebteste Forumthreads (12 Monate)

allgemeine Laufvariable für While-Schleife?

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread