Live-Forum - Die aktuellen Beiträge
Anzeige
Archiv - Navigation
664to668
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
664to668
664to668
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Beliebige Files aus Excel-Liste starten

Beliebige Files aus Excel-Liste starten
14.09.2005 16:10:11
horrscht6
Hallo,
ich habe in einer Excel-Liste viele Pfad+Dateinamen in unterschiedlichen Zellen stehen:
M:\Tschrift\...\Anweisung.doc
C:\Eigene Dateien\Example.pdf
P:\QM\organigramm.xls
M:\Vertrieb\kunden.mdb
usw. viele mehr.
Ich habe einen Button ins Excel gelegt, der je nach dem wo die ActiveCell steht, diese Datei einfach öffnen soll, wenn der Button gedrückt wird. Quasi wie ein Doppelklick auf dieselbe Datei im Explorer und schwupp die Datei würde geöffnet.
Hier der Code zur Routine beim Button:

Private Sub btnLinkOpen()
Dim Z, S As Integer
Dim Bezug As String
Z = ActiveCell.Row
S = ActiveCell.Column
Bezug = Chr(64 + S) & Trim(Str(Z))
Range(Bezug).Select    ' Jetzt wird Bezug-Variable nicht mehr benötigt
Bezug = Cells(Z, S)
If Bezug <> "" Then
If Dir(Bezug) <> "" Then     ' Findet er die Datei?
ergebnis = Shell(Bezug, vbMaximizedFocus)  ' Hier passiert der Fehler
End If
End If
End Sub

Die Fehlermeldung, die kommt, lautet: Laufzeitfehler 53 "Datei nicht gefunden"
Steht in der Liste im Excel eine ausführbare EXE-Datei funktioniert es. Bei allen anderen Dokument-Typen geht's nicht. Wer kann mir helfen?
Danke, Matthias

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Beliebige Files aus Excel-Liste starten
14.09.2005 18:17:07
Nepumuk
Hallo Matthias,
versuch es mal so:
' **********************************************************************
' Modul: Modul6 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" ( _
    ByVal hwnd As Long, _
    ByVal lpOperation As String, _
    ByVal lpFile As String, _
    ByVal lpParameters As String, _
    ByVal lpDirectory As String, _
    ByVal nShowCmd As Long) As Long

Private Declare Function GetActiveWindow Lib "user32.dll" () As Long

Private Const SW_MAXIMIZE = 3&

Private Sub btnLinkOpen()
    Dim Bezug As String
    Bezug = ActiveCell.Text
    If Bezug <> "" Then
        If Dir$(Bezug) <> "" Then
            Select Case LCase$(Right$(Bezug, 3))
                Case "xls"
                    Workbooks.Open Bezug
                Case Else
                    ShellExecute GetActiveWindow, "open", Bezug, _
                        vbNullString, vbNullString, SW_MAXIMIZE
            End Select
        End If
    End If
End Sub

Gruß
Nepumuk

Anzeige
AW: Beliebige Files aus Excel-Liste starten
14.09.2005 23:30:53
horrscht6
Danke hervorragend!
Funktioniert prima.
Gruß, Matthias

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige