ownload von bilder

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Download von Bilder

03.10.2005 02:48:02

Bilder

Frage an Nepumuk

03.10.2005 05:39:04

chris

AW: Frage an Nepumuk

03.10.2005 10:18:49

Nepumuk

AW: Frage an Nepumuk

03.10.2005 14:02:36

mehmet

AW: Frage an Nepumuk

03.10.2005 14:25:06

Nepumuk

AW: Frage an Nepumuk

03.10.2005 15:59:03

mehmet

AW: Frage an Nepumuk

03.10.2005 16:47:18

Nepumuk

AW: Frage an Nepumuk

03.10.2005 17:44:56

mehmet

AW: Frage an Nepumuk

03.10.2005 14:11:07

chris

Hi mehmet,
ist doch nicht so schwer:
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Private Declare Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" ( _
    ByVal pCaller As Long, _
    ByVal szURL As String, _
    ByVal szFileName As String, _
    ByVal dwReserved As Long, _
    ByVal lpfnCB As Long) As Long
Private Declare Function InternetDial Lib "wininet.dll" ( _
    ByVal hwndParent As Long, _
    ByVal lpszConiID As String, _
    ByVal dwFlags As Long, _
    ByRef hCon As Long, _
    ByVal dwReserved As Long) As Long
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" ( _
    ByVal lpClassName As String, _
    ByVal lpWindowName As String) As Long
Private Declare Function RasEnumConnections Lib "rasapi32.dll" Alias "RasEnumConnectionsA" ( _
    lpRasCon As Any, lpcb As Long, _
    lpcConnections As Long) As Long
Private Declare Function RasHangUp Lib "rasapi32.dll" Alias "RasHangUpA" ( _
    ByVal hRasConn As Long) As Long
Private Declare Function InternetGetConnectedState Lib "wininet.dll" ( _
    ByRef lpSFlags As Long, _
    ByVal dwReserved As Long) As Long

Private Const DIAL_FORCE_ONLINE = 1
Private Const DIAL_FORCE_UNATTENDED = 2
Private Const RAS_MAXENTRYNAME = 256
Private Const RAS_MAXDEVICETYPE = 16
Private Const RAS_MAXDEVICENAME = 32
Private Const MAX_FILL = 96

Private Type RASType
    dwSize As Long
    hRasCon As Long
    szEntryName(RAS_MAXENTRYNAME) As Byte
    szDeviceType(RAS_MAXDEVICETYPE) As Byte
    szDeviceName(RAS_MAXDEVICENAME) As Byte
    dwFill(MAX_FILL) As Byte
End Type

Public Sub prcDownload()
    Dim udtRAS(255) As RASType
    Dim lngNumBytes As Long, lngConnections As Long, lngRow As Long
    Dim blnReturn As Boolean, blnOnline As Boolean
    On Error GoTo exit_err
    If Not Cbool(InternetGetConnectedState(0&, 0&)) Then
        blnReturn = RASConnect(FindWindow("XLMAIN", Application.Caption), "", True)
        If Not blnReturn Then Err.Raise Number:=vbObjectError + 1, Description:= _
            "Internetverbindung konnte nicht erstellt werden."
    Else
        blnOnline = True
    End If
    For lngRow = 2 To Cells(Rows.Count, 3).End(xlUp).Row
        URLDownloadToFile 0&, Cells(lngRow, 3).Text, Cells(lngRow, 2).Text & "\" & _
            Cells(lngRow, 4).Text, 0&, 0&
    Next
    If Not blnOnline Then
        udtRAS(0).dwSize = 412
        lngNumBytes = 256 * udtRAS(0).dwSize
        RasEnumConnections udtRAS(0), lngNumBytes, lngConnections
        If lngConnections = 0 Then
            Err.Raise Number:=vbObjectError + 2, Description:= _
                "Fehler beim trennen der Internetverbindung."
        Else
            RasHangUp ByVal udtRAS(0).hRasCon
        End If
    End If
    Exit Sub
    exit_err:
    MsgBox "Fehler " & CStr(Err.Number) & vbLf & vbLf & _
        Err.Description, 16, "Fehler"
End Sub

Private Function RASConnect( _
        ByVal hWnd As Long, _
        Optional ByVal DFÜName As String, _
        Optional ByVal AutoStart As Boolean) As Boolean
    Dim conID As Long
    InternetDial hWnd, DFÜName, IIf(AutoStart, _
        DIAL_FORCE_UNATTENDED, DIAL_FORCE_ONLINE), conID, 0
    RASConnect = (conID <> 0)
End Function

Gruß
Nepumuk

Hallo Nepumuk,
also für mich ist der code auch nicht gerade einfach.
Aber gewusst wie.
Ich hätte da noch eine frage an dich und zwar wenn ich z.b so eine funktion habe die auf Api zugreift:
Private Declare Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" ( _
ByVal pCaller As Long, _
ByVal szURL As String, _
ByVal szFileName As String, _
ByVal dwReserved As Long, _
ByVal lpfnCB As Long) As Long
Wo finde ich heraus also gibt es eine gute seite im internet oder irgendwo mei MSDN
wo ich in erfahrung bringen kann was in den einzelnen Variablen stehen soll.
Also z.b in pCaller oder in szFileName
Wäre super wenn du eine Antwort für mich hast.
Danke und schönen Feiertag !! grüße Christian

Beliebteste Forumthreads (12 Monate)

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

ownload von bilder

9 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread