Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
720to724
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
720to724
720to724
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Telefonieren aus Excel

Telefonieren aus Excel
20.01.2006 20:40:45
plato
Hallo,
gibt es die Möglichkeit aus einer Tabelle, die Telefonnummern enthält zu telefonieren. Was braucht man wurde - und hardwaremäßig dazu (Win XP, Excel 7.0)
Gruß

2
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Telefonieren aus Excel
20.01.2006 22:49:56
Josef
Hallo Plato!
Bin mir nicht sicher, ob das unter XL7 läuft!
Angenommen die Telefonnummern stehen in Spalte "A" und der name in Spalte "B"
Kopiere den Code in die angegebenen Module.
Mit einem Doppelklick auf die Nummer, wird diese gewählt!
' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Column = 1 Then
  Cancel = True
  Call DialNumber(Target.Text, Target.Offset(0, 1).Text)
End If
End Sub


' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

'Dieser Source stammt von http://www.activevb.de
'und kann frei verwendet werden. Für eventuelle Schäden
'wird nicht gehaftet.

'Um Fehler oder Fragen zu klären, nutzen Sie bitte unser Forum.
'Ansonsten viel Spaß und Erfolg mit diesem Source!

'Dank an Olaf Quasdorff (oquasdorff@web.de)
Option Explicit

Private Declare Function tapiRequestMakeCall Lib "TAPI32.DLL" _
  (ByVal DestAddress As String, ByVal AppName As String, _
  ByVal CalledParty As String, ByVal Comment As String) As Long

Private Const TAPIERR_NOREQUESTRECIPIENT As Long = -2&
Private Const TAPIERR_REQUESTQUEUEFULL As Long = -3&
Private Const TAPIERR_INVALDESTADDRESS As Long = -4&

Public Sub DialNumber(strNumber As String, strLocation As String)
Dim strBuff As String
Dim lngResult As Long

lngResult = tapiRequestMakeCall(strNumber, CStr(Application.Caption), _
  strLocation, "")

If lngResult <> 0 Then
  strBuff = "Error dialing number : "
  
  Select Case lngResult
    Case TAPIERR_NOREQUESTRECIPIENT
      strBuff = strBuff & "No Windows Telephony dialing " & _
        "application is running and " & _
        "none could be started."
      
    Case TAPIERR_REQUESTQUEUEFULL
      strBuff = strBuff & "The queue of pending Windows " & _
        "Telephony dialing requests " & _
        "is full."
      
    Case TAPIERR_INVALDESTADDRESS
      strBuff = strBuff & "The phone number is not valid."
      
    Case Else
      strBuff = strBuff & "Unknown error."
      
  End Select
  
  MsgBox strBuff
End If
End Sub


'******************************
'* Gruß Sepp
'*
'* Rückmeldung wäre nett!
'******************************

Anzeige
AW: Telefonieren aus Excel
21.01.2006 03:13:40
Thomas
Hallo,
Für Besitzer einer Fritzbox-Fon gibt's ab ca. 02.02.2006 dieses Produkt; es soll dann auch in einer befristeten Testversion verfügbar sein :
Entwurf/Vorabinfo: http://www.tt-edv-beratung.de/Flyer-FBF-Dialer-tt2.pdf
Preis steht noch nicht fest, aber zweistellig Euro/PC. Bei Interesse bitte einfach melden.
Man braucht:
o einen Telefonanschluß ( analog und/oder ISDN und/oder DSL ),
o eine FritzBox Fon (Firmware xx.xx.89 oder neuer),
o daran angeschlossen über LAN oder WLAN einem XP-PC mit neuerem Excel,
o ebenfalls an die FritzBox angeschlossen ein Telefon analog und/oder ISDN und
o die oben genannte Software .
HTH + Gruß
TT
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige