VBA Project vor Vesand löschen

Hallo,
in einer Tabelle habe ich 2 CommandButtons erstellt. Die Tabelle wird in eine neue Arbeitsmappe kopiert und soll anschließend per Outlook als Fax versendet werden.
Mein Problem besteht jetzt darin die 2 CommandButtons vor den Vesand zu löschen da die Datei sonst von unserer Firewall geblockt wird.
Die Commandbuttons habe ich nach den Kopieren mit folgenden Code gelöscht.
' Makros und Schaltflächen werden entfernt
ActiveSheet.Shapes("Button 1").Select
Selection.Cut
ActiveSheet.Shapes("CmdEingabeStart").Select
Selection.Cut
ActiveSheet.Shapes("CmdBeenden").Select
Selection.Cut
Wie müßte der Code aussehen um auch den dazugehörenden VBA-Code zu löschen?
Der VBA-Code für die CommandButtons steht in der Tabelle1 und lautet folgendermaßen


Private Sub CmdBeenden_Click()
Application.CutCopyMode = False
ActiveWorkbook.Close False
End Sub


Private Sub CmdEingabeStart_Click()
usrAbfrage.Show
End Sub

Vielen Dank im voraus für Eure HIlfe.
Gruß
J.Freitag

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Jakob,
hier eine Funktion den den gesmaten Code einer angegebenen Datei löscht.


Function VBACode_Komplett_Loeschen(wkbMappe As Workbook)
' Achtung diese Funktion löscht den kompletten VBA Code der angegebenen Datei !!!
Dim objVBA As Object
Dim strFile As String
With wkbMappe.VBProject
' Ein Schleife die ALLE VBComponents durchläuft, sollen nur bestimmte gelöscht werden
' dann muss dieser Code angepaßt werden.
For Each objVBA In .VBComponents
Select Case objVBA.Type
' Wenn Type = 1 dann ist es ein Standardmodul, dies wird komplett gelöscht!
Case 1
.VBComponents.Remove .VBComponents(objVBA.Name)
' Wenn Type = 2 dann ist es ein Klassennmodul, dies wird komplett gelöscht!
Case 2
.VBComponents.Remove .VBComponents(objVBA.Name)
' Wenn Type = 3 dann ist es ein Userform, dies wird komplett gelöscht!
Case 3
.VBComponents.Remove .VBComponents(objVBA.Name)
' Wenn Type = 100, also DieseArbeitsmappe oder ein Tabellenblatt, dann darin
' alle Codezeilen löschen. Denn die Datei und die Tabellenblätter sollen ja
' erhalten bleiben, also nur den Code löschen.
Case 100
With .VBComponents(objVBA.Name).CodeModule
.DeleteLines 1, .CountOfLines
End With
Case Else
MsgBox "Unbekannter VBA Type !", vbCritical
End Select
Next objVBA
End With
wkbMappe.Save
Exit Function
' Bei Fehlernummer 1004, diese Meldung ausgeben.
Errorhandler:
If Err.Number = 1004 Then
MsgBox "Das Löschen des VBA Codes ist fehlgeschlagen!" & vbCr & _
"Bitte überprüfen Sie folgende Einstellung! " & vbCr & _
"EXTRAS -> MAKRO -> SICHERHEIT -> Vertrauenwürdige Quellen." & vbCr & _
"'Zugriff auf Visual Basic Projekt vertrauen' muss aktiviert sein! ", vbCritical, _
" Meldung vom Makro VBAloeschen"
Else
MsgBox "Err.Number = " & Err.Number & ".   " & Err.Description, vbCritical
End If
End Function

' Aufrufen z.B. so


Sub Test()
VBACode_Komplett_Loeschen Workbooks("Mappe4.xls")
End Sub

Gruß Heiko
PS: Rückmeldung wäre nett !

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

VBA Project vor Vesand löschen

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread