selbststartendes Makro für regelmäßige Aktualisier

Guten Morgen alle miteinander!
Ich habe eine Datei mit vielen externen Verknüpfungen, von denen nur eine aller 10 min aktualisiert werden soll.
Dazu hab ich aus der Recherche ein kleines Makro gefunden, daß das schafft.


Private Sub Aktualisieren()
ActiveWorkbook.UpdateLink Name:="H:\aktuell\Basis\Central.xls", Type:= _
xlExcelLinks
ActiveWorkbook.Save
Application.OnTime Now + TimeValue("00:10:00"), "Aktualisieren"
End Sub

Dazu habe ich 2 Probleme:
1. Nach Schließen der Datei kommt wieder nach Ablauf der 10min einmalig die
Fehlermeldung von MS-VB "Argument ist nicht optional"
Wie kriege ich die weg?
2. Wie kann ich den Start des Makros an das Öffnen der Datei binden?
Irgendwie muß das gehen mit

Private Sub Workbook_Open()
aber ich krieg das nicht hin
Ich hoffe, für die freaks ist das ein "Klacks" - für mich ist hier schon Schluß.
Einen schönen Tag noch!
Klaus

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Klaus!
Ich mache das immer so.

' **********************************************************************
' Modul: DieseArbeitsmappe Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Workbook_BeforeClose(Cancel As Boolean)
StopTimer
End Sub

Private Sub Workbook_Open()
StartTimer
End Sub

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public RunWhen As Double
Public Const cRunIntervalSeconds = 600 ' Intervall in Sekunden
Public Const cRunWhat = "Aktualisieren"

Sub StartTimer()
RunWhen = Now + TimeSerial(0, 0, cRunIntervalSeconds)
Application.OnTime earliesttime:=RunWhen, procedure:=cRunWhat, _
  schedule:=True
End Sub

Sub StopTimer()
On Error Resume Next
Application.OnTime earliesttime:=RunWhen, _
  procedure:=cRunWhat, schedule:=False
End Sub

Private Sub Aktualisieren()

ActiveWorkbook.UpdateLink _
  Name:="H:\aktuell\Basis\Central.xls", _
  Type:=xlExcelLinks

ActiveWorkbook.Save

StartTimer

End Sub

Gruß Sepp

Beliebteste Forumthreads (12 Monate)

selbststartendes Makro für regelmäßige Aktualisier

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

selbststartendes Makro für regelmäßige Aktualisier

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread