Gültigkeitsbereich für Textboxen

Hallo,
ich habe ein Problem bei der VBA Programmierung.
Ich habe eine Userform erstellt und gereriere dynamisch 120 Textfelder.
oben=30
for i = 0 to 199
set answa(i) = controls.add("forms.textbox.1", ,true)
with answa(i)
.left =45
.top=oben
.width=30
.height=15
select case i
case 0: .text=""
case 1: .text=""
usw
case199: .text=""
end select
end with
oben =oben+30
next i
das erzeugen der Textboxen funktioniert auch einwandfrei
es dürften allerdings nur zahlen zwischen 1 und 5 eingetragen werden
deshalb meine frage: wie kann ich einen gültigkeitsbereich für die Textboxen (alle 120 haben die gleiche Restriktion Zahlen zwischen 1 und 5) in die schleife einbauen?
Vielen Dank für die Hilfe
Michael

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Michael,
ein leeres UF, ein Klassenmodul mit dem namen "clsTB" und diesen Code. Einfach mal probieren.
' **********************************************************************
' Modul: clsTB Typ: Klassenmodul
' **********************************************************************

Option Explicit

Private WithEvents TBox As MSForms.TextBox

Public Function Init(TB As MSForms.TextBox) As Object
Set Init = Nothing
Set TBox = TB
Set Init = Me
End Function

Private Sub TBox_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
Select Case KeyAscii
    Case 49 To 53 'Zahlen von 1 bis 5
    Case Else
        KeyAscii = 0
End Select
End Sub

' **********************************************************************
' Modul: UserForm1 Typ: Userform
' **********************************************************************

Option Explicit
Dim TxtBox() As clsTB

Private Sub UserForm_Initialize()
Dim iTop As Integer, iLeft As Integer, iIndex As Integer
Dim objTB As MSForms.TextBox

Me.Height = 450
Me.Width = 380

iTop = 15
iLeft = 15

For iIndex = 1 To 200
    Set objTB = Controls.Add("forms.textbox.1", , True)
    With objTB
        .Left = iLeft
        .Top = iTop
        .Width = 30
        .Height = 15
        .MaxLength = 1
        .Tag = CStr(iIndex)
    End With

    Redim Preserve TxtBox(iIndex)
    Set TxtBox(iIndex) = New clsTB
    TxtBox(iIndex).Init objTB

    Set objTB = Nothing

    iTop = iTop + 18
    If iIndex Mod 20 = 0 Then
        iTop = 15
        iLeft = iLeft + 35
    End If
Next
End Sub

Gruß Sepp

Beliebteste Forumthreads (12 Monate)

Gültigkeitsbereich für Textboxen

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Gültigkeitsbereich für Textboxen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

300 Forumthreads zu ähnlichen Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread