AW: Benannte Bereiche kopieren
24.05.2007 22:17:43
fcs
Hallo Specke,
grundsätzlich kann man dem kopierten Bereich in der Zieltabelle den gleichen Namen zuweisen wie in der Quelltabelle. Allerdings muss du dann, wenn du den Bereich innerhalb der Arbeitsmappe in eine andere Tabelle kopierst, dem Bereichsnamen den Namen der Zieltabebelle voranstellen (z.B. Tabelle2!Bereichsname) . Beim Kopieren in die Tabelle einer anderen Arbeitsmappe kannst die gleichen Namen direkt verwenden
Gruß
Franz
Beispielmakros bei Auswahl via Combobox:
'Variante, wenn Zieltabelle in der gleichen Arbeitsmappe liegt
Private Sub ComboBox1_Change()
Dim wbQ As Workbook, wbZ As Workbook
Dim wksQ As Worksheet, wksZ As Worksheet
Dim strBereichQ$, strBereichZ$
Dim rngBereichQ As Range, rngBereichZ As Range
Set wbQ = ThisWorkbook
Set wbZ = ThisWorkbook
ActiveSheet.Range("A1").Select
Select Case Me.ComboBox1.Value
Case "Bereich01"
strBereichQ = "Bereich01" 'Bereichsname in Quelltabelle
Set wksZ = wbZ.Worksheets(2) 'Objektzuweisung für Zieltabelle
strBereichZ = "$B$2" 'Zelladdresse der linken oberen Ecke des Einfügebereichs
Case "Bereich02"
strBereichQ = "Bereich02"
Set wksZ = wbZ.Worksheets(2)
strBereichZ = "$F$2"
End Select
Set rngBereichQ = Application.Range(strBereichQ) 'Range-Objekt für Quellbereich
With wksZ
'Range-Objekt für Zielbereich festlegen
Set rngBereichZ = .Range(.Range(strBereichZ), .Range(strBereichZ).Offset(rngBereichQ.Rows. _
Count - 1, rngBereichQ.Columns.Count - 1))
'Zellen Kopieren
rngBereichQ.Copy Destination:=rngBereichZ
'Zellenbereich in Zieltabelle den gleichen NAmen zuweisen wie in Quelltabelle
wbZ.Names.Add Name:="'" & wksZ.Name & "'!" & strBereichQ, RefersTo:="='" & wksZ.Name & "'!" _
& rngBereichZ.Address
End With
End Sub
'Variante, wenn Zieltabelle in einer anderen Arbeitsmappe liegt
Private Sub ComboBox1_Change()
Dim wbQ As Workbook, wbZ As Workbook
Dim wksQ As Worksheet, wksZ As Worksheet
Dim strBereichQ$, strBereichZ$
Dim rngBereichQ As Range, rngBereichZ As Range
Set wbQ = ThisWorkbook
Set wbZ = Workbooks("BereicheKopierenZ.xls")
ActiveSheet.Range("A1").Select
Select Case Me.ComboBox1.Value
Case "Bereich01"
strBereichQ = "Bereich01" 'Bereichsname in Quelltabelle
Set wksZ = wbZ.Worksheets(2) 'Objektzuweisung für Zieltabelle
strBereichZ = "$B$2" 'Zelladdresse der linken oberen Ecke des Einfügebereichs
Case "Bereich02"
strBereichQ = "Bereich02"
Set wksZ = wbZ.Worksheets(2)
strBereichZ = "$F$2"
End Select
Set rngBereichQ = Application.Range(strBereichQ) 'Range-Objekt für Quellbereich
With wksZ
'Range-Objekt für Zielbereich festlegen
Set rngBereichZ = .Range(.Range(strBereichZ), .Range(strBereichZ).Offset(rngBereichQ.Rows. _
Count - 1, rngBereichQ.Columns.Count - 1))
'Zellen Kopieren
rngBereichQ.Copy Destination:=rngBereichZ
'Zellenbereich in Zieltabelle den gleichen NAmen zuweisen wie in Quelltabelle
wbZ.Names.Add Name:=strBereichQ, RefersTo:="='" & wksZ.Name & "'!" & rngBereichZ.Address
End With
End Sub