Commandbars Enable = False + MSGBox

Hallo zusammen,
ich habe in einer Datei in "Diese Arbeitsmappe" ein Workbook_Activate() Ereignis gesetzt, in dem ich die Anweisung Application.CommandBars("ply").Enabled = False untergebracht habe, die verhindert, dass ein Rechtsklick auf die Tabellenblätter funktioniert. Nun hätte ich gern hierzu noch eine Messagebox mit einem Hinweis geschrieben, der aussagt, dass genau diese Funktion deaktiviert ist.
Wenn man z. B. Alt+F11 deaktiviert, kann man einen Hinweistext dazu schreiben. Entsprechende Anweisungen dazu habe ich hier im Forum gefunden:
Application.OnKey "%{F11}", "VBAMessage"


Sub VBAMessage()
MsgBox "Diese Funktion ist deaktiviert.", vbInformation, "Fehler"
End Sub

Leider funktioniert das nicht mit dem oben genannten Enabled = False Ereignis. Ich möchte, falls jemand mit der rechten Maustaste auf eine Blattregisterkarte klickt, anstatt der üblichen Funktion nur eine MSGBox erhalten. Wie geht das?
Vielen Dank schonmal im Voraus!
Grüße,
Marc Richter

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo
Das gehört in das Klassenmodul "Diese Arbeitsmappe" deiner Mappe wo das funktionieren soll

Option Explicit

Private Sub Workbook_Open()
Disable_Ply_Commandbar
End Sub

Das gehört in ein VBA-Modul deiner Mappe

Option Explicit

Sub Disable_Ply_Commandbar()
    Dim myCb As CommandBar
    Dim myCtl As CommandBarControl
    Set myCb = CommandBars("Ply")
    Dim i As Integer
    With myCb
        .Reset
        For i = .Controls.Count To 1 Step -1
            .Controls(i).Delete
        Next i
    End With
    Set myCtl = myCb.Controls.Add()
    With myCtl
        .Caption = "Diese Funktion wurde deaktiviert"
        .OnAction = ""
    End With
    Set myCtl = myCb.Controls.Add()
    With myCtl
        .Caption = "Funktion aktivieren"
        .OnAction = "Activate_Ply_Bar"
    End With
    Set myCb = Nothing
    Set myCtl = Nothing
End Sub

Sub Activate_Ply_Bar()
    Dim myCb As CommandBar
    Dim myCtl As CommandBarControl
    Set myCb = CommandBars("Ply")
    Dim myPass As String, inPass As String
    myPass = "DeinPasswort"
    inPass = InputBox("Passwort eingeben:", "Admin Funktion", "Das ist es nicht")
    'Abbrechen geklickt
    If StrPtr(inPass) = 0 Then Exit Sub
    'Passwort falsch
    If inPass <> myPass Then Exit Sub
    CommandBars("Ply").Reset
    Set myCtl = myCb.Controls.Add()
    With myCtl
        .Caption = "Reiter Kontextmenü deaktivieren"
        .OnAction = "Disable_Ply_Commandbar"
    End With
    MsgBox "Kontextmenü aktiviert"
End Sub

Viel Spass
Gruss Rainer

Beliebteste Forumthreads (12 Monate)

Commandbars Enable = False + MSGBox

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Commandbars Enable = False + MSGBox

13 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread