Wochen nach Datum ermitteln

Moin, moin,
mal 'ne Frage, bzw. ein Problem an die Profis - vielleicht sehe ich auch den Wald vor lauter Bäumen nicht?
Ich suche folgende Möglichkeit:
Spalte A ist Wocheneintrag (als 1, 2, 3 , usw.) aktuell ist 32
Spalte B zeigt mir den Zeiraum an (01.01 bis 07.01, 08.01 bis 14.01) aktuell ist 06.09. bis 12.09 (müßte in einer Zelle/Spalte stehen).
In Spalte C und D kommen eigene Werte.
Weiterhin (irgendwo z. b. in A1) ein Feld o. ä. wo die Jahreszahl angegeben wird, aus welcher sich dann die Zeiträume in Spalte B errechnen, unter Berücksichtigung eines Jahres, was bedeuten könnte, Woche 1 und/oder Woche 52 haben nicht 7 Tage.
Für jeden Hinweis oder Hilfestellung wäre ich dankbar.
MfG wolfgang w.w

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Wolfgang,
eine KW nach ISO, also unsere KW hat im immer 7 Tage und kann jahrübergreifend sein. Eine 53. KW ist in abestimmten Jahren möglich. Die "amerikanische" KW hat nicht immer 7 Tage und ist nicht jahrübergreifend, nur 52 KW sind hier möglich.

	A	B	C	D	E
1		KW aus Datum
2		Mi, 08.03.2006	10
3		KW heute
4			32
5
6		Datum aus KW
7		KW/Jahr	Wochenanfang	Wochenende	Woche Zusammengefasst, ist Text!!
8		2/05	Mo, 10.01.2005	So, 16.01.2005	Mo, 10.01.2005 - So, 16.01.2005
9
10	Jahr	KW	Wochenanfang	Wochenende	Woche Zusammengefasst, ist Text!!
11	2005	2	10.01.2005	16.01.2005	10.01.2005 - 16.01.2005
12		2	####	###	10.01.2005 - 16.01.2005

Formeln der Tabelle

C2 : =WENN(ISTZAHL(B2); KÜRZEN((B2-WOCHENTAG(B2;2)-DATUM(JAHR(B2+4-WOCHENTAG(B2;2)); 1;-10))/7); "")
C4 : =KÜRZEN((HEUTE()-WOCHENTAG(HEUTE(); 2)-DATUM(JAHR(HEUTE()+4-WOCHENTAG(HEUTE(); 2)); 1;-10))/7)
C8 : =WENN(B8="";"";DATUM(JAHR(WERT("1.1."&TEIL(B8;SUCHEN("/";B8)+1;4))); 1;7*TEIL(B8;1;SUCHEN("/";B8)-1)-3-WOCHENTAG(DATUM(JAHR(WERT("1.1."&TEIL(B8;SUCHEN("/";B8)+1;4))); ;); 3)))
D8 : =WENN(B8="";"";DATUM(JAHR(WERT("1.1."&TEIL(B8;SUCHEN("/";B8)+1;4))); 1;7*TEIL(B8;1;SUCHEN("/";B8)-1)-3-WOCHENTAG(DATUM(JAHR(WERT("1.1."&TEIL(B8;SUCHEN("/";B8)+1;4))); ;); 3)))+6
E8 : =TEXT(C8;"TTT, TT.MM.JJJ")&" - "&TEXT(D8;"TTT, TT.MM.JJJ")
C11 : =DATUM($A$11;1;7*B11-3-WOCHENTAG(DATUM($A$11;;); 3))
D11 : =DATUM($A$11;1;7*B11-3-WOCHENTAG(DATUM($A$11;;); 3))+6
E11 : =TEXT(C11;"TT.MM.JJJ")&" - "&TEXT(D11;"TT.MM.JJJ")
E12 : =TEXT(DATUM($A$11;1;7*B12-3-WOCHENTAG(DATUM($A$11;;); 3)); "TT.MM.JJJ")&" - "&TEXT(DATUM($A$11;1;7*B12-3-WOCHENTAG(DATUM($A$11;;); 3))+6;"TT.MM.JJJ")

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
MfG
Rüdigere Lenz

Beliebteste Forumthreads (12 Monate)

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread