AW: statt kopieren auschneiden
23.09.2007 02:00:37
fcs
Hallo Lisa,
Mit der Methode Cut können nur zusammenhängende Zellebereiche ausgeschnitten und woanders wieder eingefügt werden.
Wenn du gefilterte Daten ausschneiden/einfügen möchtest, dann muss dies zeilen-/blockweise erfolgenden.
Ich hab deine Prozedur mal entsprechend umgestellt. In einer Schleife werden dabei nur die sichtbaren zeilen aausgeschnitten und kopiert. In einer 2. Schleife werden die jetzt leeren Zeilen gelöscht. Für das Prüfen, ob der Autofilter gesetzt ist hab ich eine etwas andere (direktere Methode) verwendet.
MfG
Franz
Sub DatenübernahmeDatenbank()
Dim wksZiel As Worksheet, wksData As Worksheet
Dim lRow As Long, lZeile As Long, lTest As Long, start As Long
Dim fFilter As Filter, bFilterAktiv As Boolean
Set wksData = Worksheets("Datenbank")
Set wksZiel = Worksheets("Tabelle2")
With wksData
'Prüfen ob Autofilter Aktiv
If .AutoFilterMode = True Then
For Each fFilter In .AutoFilter.Filters
If fFilter.On Then bFilterAktiv = True: Exit For
Next
Else
bFilterAktiv = False
End If
If Not bFilterAktiv Then
MsgBox "Kein Autofilter aktiv!", vbOKOnly + vbExclamation, "kopieren"
GoTo beenden
End If
'Altdaten in Zieltabelle Spalten A bis I löschen ?
lTest = MsgBox("Altdaten in Zieltabelle löschen?", vbQuestion + vbYesNoCancel, _
"Ausschneiden, verschieben")
If lTest = vbYes Then
lRow = wksZiel.Cells(wksZiel.Rows.Count, 1).End(xlUp).Row
If lRow >= 2 Then
wksZiel.Range(wksZiel.Cells(2, 1), wksZiel.Cells(lRow, 9)).ClearContents
End If
ElseIf lTest = vbCancel Then
GoTo beenden
End If
Application.EnableEvents = False
Application.ScreenUpdating = False
'Nächste leere Zeile in Zieltabelle
lRow = wksZiel.Cells(wksZiel.Rows.Count, 1).End(xlUp).Row + 1
'gefilterte Zeilen ausschneiden und in Zieltabelle einfügen
lTest = .Cells(.Rows.Count, 1).End(xlUp).Row
For lZeile = 3 To lTest
If .Rows(lZeile).Hidden = False Then
start = lZeile
Do Until .Rows(lZeile).Hidden = True Or lZeile > lTest
lZeile = lZeile + 1
Loop
.Range(.Rows(start), .Rows(lZeile - 1)).Cut Destination:=wksZiel.Cells(lRow, 1)
lRow = lRow + lZeile - start
End If
Next
Application.CutCopyMode = False
'leere gefilterte Zeilen löschen
'Prüfen ob noch ausgeblendete Zeilen vorhanden
If .Cells.SpecialCells(xlCellTypeVisible).Count .Cells.Count Then
.ShowAllData
For lZeile = lTest To 3 Step -1
If IsEmpty(.Cells(lZeile, 1)) Then
start = lZeile
Do Until Not IsEmpty(.Cells(lZeile, 1))
lZeile = lZeile - 1
Loop
.Range(.Rows(lZeile + 1), .Rows(start)).Delete shift:=xlShiftUp
End If
Next
End If
Application.ScreenUpdating = True
Application.EnableEvents = True
.Range("a1").Select
Selection.ClearContents ' ?
MsgBox "Gefilterte Daten wurden nach " & wksZiel.Name & " kopiert!", _
vbOKOnly + vbInformation, "ausschneiden und verschieben"
End With
With wksZiel
.Activate
' .Range("A3:i120").ClearContents ?
End With
beenden:
Set wksZiel = Nothing: Set wksData = Nothing: Set fFilter = Nothing
End Sub