bedingte formatierung für werte in spez. spalte

hallo zusammen. bitte um eure mithilfe in meiner kleinen vba-problematik
möchte mein sheet auf bestimmte werte abfragen und mit die identifizierten zellen mit einer bestimmten hintergrundfarbe versehen. hab dazu die untenstehenden anweisungen geschrieben. die sache funktioniert soweit gut. nun möcht ich das ganze aber nur für bestimmte spalten durchführen. dh. ich suche die spalte "ordnung", gebe die zu suchenden werte an und möchte diese dann mit einer speziellen hintergrundfarbe versehen. kann mir jemand helfen meinen code dementsprechend anzupassen?


Sub start()
Dim strfalseValue1 As String
Dim strfalseValue2 As String
Dim strfalseValue3 As String
strfalseValue1 = "gering"
strfalseValue2 = "extrem"
strfalseValue3 = "stark"
Call Ordnung_einfaerben(strfalseValue1, strfalseValue2, strfalseValue3)
End Sub


Sub Ordnung_einfaerben(ByRef strfalseValue1, strfalseValue2, strfalseValue3)
Dim c As Object
For Each c In ActiveSheet.UsedRange
If c = strfalseValue1 Then
c.Interior.ColorIndex = 4
ElseIf c = strfalseValue2 Then
c.Interior.ColorIndex = 6
ElseIf c = strfalseValue3 Then
c.Interior.ColorIndex = 3
End If
Next c
End Sub

tausend dank,
rudi

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Rudi,
probier mal.
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub start()
Dim strfalseValue1 As String, strfalseValue2 As String, strfalseValue3 As String
Dim strSearch As String, lngRow As Long

strSearch = "Ordnung" ' Suchbegriff
lngRow = 1 ' Zeile in der nach "Suchbegriff" gesucht wird
strfalseValue1 = "gering"
strfalseValue2 = "extrem"
strfalseValue3 = "stark"

Call Spalte_einfaerben(strSearch, lngRow, strfalseValue1, strfalseValue2, strfalseValue3)

End Sub

Sub Spalte_einfaerben(ByVal strSearch As String, ByVal lngSrchRow As Long, _
    ByVal strfalseValue1 As Variant, ByVal strfalseValue2 As Variant, _
    ByVal strfalseValue3 As Variant)

Dim rng As Range, rngCol As Range, c As Range

Set rng = Rows(lngSrchRow).Find(What:=strSearch, _
    LookAt:=xlWhole, _
    LookIn:=xlValues, _
    MatchCase:=False)

If Not rng Is Nothing Then

    On Error Resume Next
    Set rngCol = rng.EntireColumn.SpecialCells(xlCellTypeConstants)
    On Error GoTo 0

    If Not rngCol Is Nothing Then
        For Each c In rngCol
            Select Case c.Value
                Case strfalseValue1
                    c.Interior.ColorIndex = 4
                Case strfalseValue2
                    c.Interior.ColorIndex = 6
                Case strfalseValue3
                    c.Interior.ColorIndex = 3
                Case Else
                    c.Interior.ColorIndex = xlNone
            End Select
        Next
    End If
End If

Set rng = Nothing
Set rngCol = Nothing
Set c = Nothing
End Sub

Gruß Sepp

Beliebteste Forumthreads (12 Monate)

bedingte formatierung für werte in spez. spalte

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

318 Forumthreads zu ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

bedingte formatierung für werte in spez. spalte

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

318 Forumthreads zu ähnlichen Themen

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread