ein Optionsfeld soll mir sagen, dass die Zeilen ausgeblendet werden sollen, in denen (z.B.) eine "1" steht.
Bin leider kein VBA-Kenner, sorry. Bekommt man so etwas leicht hin?
Viele Grüße, Thomas
Private Sub OptionButton1_Click() 'optionbutton Name mußt du evt. anpassen
Dim i As Integer
For i = 2 To 5000 'Dieser Teil durchsucht Spalte A von Zeile 2 bis Zeile 5000 nach dem wert 1
If Sheets("Tabelle1").Cells(i, 1) = 1 Then
Range("A" & i).Select 'Dieser Teil blendet be gefundenem Wert die entsprechende Zeile aus
Selection.EntireRow.Hidden = True
End If
Next i
End Sub
füge dieses Makro in ein Standardmodul ein.
zum einblenden nimmst du am besten einen zweiten optionsbutton und weist ihm diesen code zu:
Private Sub OptionButton2_Click()
Rows("2:5000").Select
Selection.EntireRow.Hidden = False
End Sub
Rückmeldung wäre nett
Gruß´
Thorsten
Private Sub OptionButton1_Click() 'optionbutton Name mußt du evt. anpassen
Dim i As Integer
For i = 2 To 5000
If Me.Cells(i, 1) = 1 Then Rows(i).Hidden = True
Next i
End Sub
Private Sub OptionButton2_Click()
Rows.Hidden = False
End Sub
Hier noch eine Alternative mit einer CheckBox und Find:
Option Explicit
Private Sub CheckBox1_Click()
Dim rngF As Range
If CheckBox1 Then
With Cells
Set rngF = .Find(What:=1, _
LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByRows, _
SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=False)
If Not rngF Is Nothing Then
Do
Rows(rngF.Row).Hidden = True
Set rngF = .FindNext(Cells(rngF.Row, .Columns.Count))
Loop While Not rngF Is Nothing
End If
End With
Else
Rows.Hidden = False
End If
End Sub
und eine Beispielmappe:
https://www.herber.de/bbs/user/49087.xls
Rückmeldung wäre nett! - Grüße von Erich aus Kamp-Lintfort
so viele Selects müssen nicht sein
. Ich weis, aber da bin ich mir noch unsicher. Nun bin ich aber wieder ein Stück weiter... Danke für deinen Input :-)
Gruß
Thorsten