Anzeige
Archiv - Navigation
984to988
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
984to988
984to988
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Tabellenausschnitt aus JPG speichern
14.06.2008 15:00:00
Peter
Hallo,
ich habe das Makro

Die Datei https://www.herber.de/bbs/user/37065.xls wurde aus Datenschutzgründen gelöscht

in einigen Excel Files von mir eingebaut um „Bilder zu schiessen“.
Seit gestern bin ich auf Office 2007 (davor Office 2000) umgestiegen und bekomme beim Aufruf des Makros nun folgenden Fehler:
Laufzeitfehler -2147024809 (80070057)
Das Element mit dem angegebenem Namen wurde nicht gefunden.
Bei folgender Zeile ihres Makros stoppt das Makro:
ActiveSheet.Shapes(Obnavn).ScaleHeight Hincrease, _
msoFalse, msoScaleFromTopLeft
Leider bin ich nicht in der Lage den Fehler zu finden und würden mich riesig freuen, wenn mir mit einen Tipp geholfen wird.
Schon im voraus herzlichen Dank.
Viele Grüße
Peter aus Würzburg

6
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Tabellenausschnitt aus JPG speichern
14.06.2008 15:07:51
mumpel
Hallo!
Das liegt an Office 2007. Einige VBA-Funktionen funktionieren in Office 2007 nicht mehr, wozu auch die von Dir genannte Funktion gehört. Hier muss auf einen anderen Code umgestellt werden.
Gruß, Rene

AW: Tabellenausschnitt aus JPG speichern
14.06.2008 15:13:40
Peter
Hallo Rene,
Schon mal Danke für die schnelle Antwort. Wie muss ich das betreffende Makro ändern ? Möchte nur ungern wieder auf Office 2000 umsteigen, nachdem ich nun Office 2007 installiert habe.
Gruß, Peter

AW: Tabellenausschnitt aus JPG speichern
14.06.2008 15:15:00
mumpel
Da bin ich überfragt. Aber die Profis hier werden sich bestimmt zu Wort melden.

AW: Tabellenausschnitt aus JPG speichern
14.06.2008 17:17:00
Josef
Hallo Peter,
so läuf's auch unter xl2007
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

'Harold Staff -- see http://www.geocities.com/davemcritchie/excel/xl2gif.htm
'XL2GIF_module -- GIF_Snapshot
Dim container As Chart
Dim containerbok As Workbook
Dim Sourcebok As Workbook

Function SelectArea() As String
Dim Internrange As Range
On Error GoTo Brutt
Set Internrange = Application.InputBox("Auswahl " _
    & "der markierten Zellen bestätigen:", "Bild-Auswahl", _
    Selection.AddressLocal, Type:=8)
SelectArea = Internrange.Address
Exit Function
Brutt:
SelectArea = "A1"
End Function

Function sShortname(ByVal Orrginal As String) As String
Dim iii As Integer
sShortname = ""
For iii = 1 To Len(Orrginal)
    If Mid(Orrginal, iii, 1) <> " " Then _
        sShortname = sShortname & Mid(Orrginal, iii, 1)
Next
End Function

Private Sub ImageContainer_init()
Workbooks.Add (1)
ActiveSheet.Name = "GIFcontainer"
Charts.Add
ActiveChart.ChartType = xlColumnClustered
ActiveChart.SetSourceData Source:=Worksheets(1).Range("A1")
ActiveChart.Location Where:=xlLocationAsObject, _
    Name:="GIFcontainer"
ActiveChart.ChartArea.ClearContents
Set containerbok = ActiveWorkbook
Set container = ActiveChart
End Sub

Sub MakeAndSizeChart(ih As Integer, iv As Integer)
Dim Hincrease As Single
Dim Vincrease As Single
Hincrease = ih / ActiveChart.ChartArea.Height
ActiveSheet.Shapes(1).ScaleHeight Hincrease, _
    msoFalse, msoScaleFromTopLeft
Vincrease = iv / ActiveChart.ChartArea.Width
ActiveSheet.Shapes(1).ScaleWidth Vincrease, _
    msoFalse, msoScaleFromTopLeft
End Sub

Public Sub GIF_Snapshot()
Dim varReturn As Variant
Dim MyAddress As String
Dim SaveName As Variant
Dim MySuggest As String
Dim Hi As Integer
Dim Wi As Integer
Dim Suffiks As Long
Set Sourcebok = ActiveWorkbook
MySuggest = sShortname(ActiveSheet.Name)
ImageContainer_init
Sourcebok.Activate
MyAddress = SelectArea
If MyAddress <> "A1" Then
    SaveName = Application.GetSaveAsFilename( _
        InitialFileName:=MySuggest _
        & ".jpg", fileFilter:="JPG Files (*.jpg), *.jpg")
    Range(MyAddress).Select
    Selection.CopyPicture Appearance:=xlScreen, _
        Format:=xlBitmap
    If SaveName = False Then
        GoTo Avbryt
    End If
    If InStr(SaveName, ".") Then SaveName _
        = Left(SaveName, InStr(SaveName, ".") - 1)
    Selection.CopyPicture Appearance:=xlScreen, _
        Format:=xlBitmap
    Hi = Selection.Height + 4 'adjustment for gridlines
    Wi = Selection.Width + 6 'adjustment for gridlines
    containerbok.Activate
    ActiveSheet.ChartObjects(1).Activate
    MakeAndSizeChart ih:=Hi, iv:=Wi
    ActiveChart.Paste
    ActiveChart.Export Filename:=LCase(SaveName) & _
        ".jpg", FilterName:="JPG"
    ActiveChart.Pictures(1).Delete
    Sourcebok.Activate
End If
Avbryt:
On Error Resume Next
Application.StatusBar = False
containerbok.Close False
End Sub


Gruß Sepp



Anzeige
AW: Tabellenausschnitt aus JPG speichern
14.06.2008 18:41:18
Peter
Lieber Sepp,
vielen vielen Dank. Jetzt klappt es auch unter Excel 2007.
Ein Superforum, selten eine solche Hilfsbereitschaft im Internet erlebt.
Schönes Wochenende und am Montag hoffentlich einen Sieg gegen Österreich, ansonsten werden wir von den Ösis 50 Jahre an das Wunder von Wien erinnert.
Viele Grüße
Peter

AW: Tabellenausschnitt aus JPG speichern
14.06.2008 17:28:37
Tino
Hallo,
habe die Namen durch eine Nummer ersetzt und es funktioniert bei mir, habe jetzt nicht nachgesehen warum es mit dem Namen nicht funktioniert aber bestimmt waren diese falsch.
https://www.herber.de/bbs/user/53072.xls
Gruß Tino

www.tinomargit.com


Anzeige

261 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige