Microsoft Excel

Excel und VBA: Formeln, Programmierung, Lösungen

Die Excel/VBA-Beispiele

Thema

Symbolleisten beim Öffnen aus-, beim Schließen einblenden

Gruppe

Open

Problem

Wie kann ich alle Symbolleisten beim Öffnen der Arbeitsmappe ausund beim Schlißen wieder einblenden lassen?

Lösung
Geben Sie den Ereigniscode in das Klassenmodul der Arbeitsmappe ein.

ClassModule: DieseArbeitsmappe

Private Sub Workbook_Open()
   Dim oBar  As CommandBar
   Dim iRow As Integer
   For Each oBar In Application.CommandBars
      If oBar.Visible And oBar.Type <> _
         msoBarTypeMenuBar Then
            iRow = iRow + 1
            With ThisWorkbook.Worksheets("CmdBars")
               .Cells(iRow, 1).Value = oBar.Name
               oBar.Visible = False
            End With
        End If
    Next oBar
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
   Call CmdBarsEin
End Sub

StandardModule: basMain

Sub WksAus()
   Worksheets("CmdBars").Visible = xlVeryHidden
End Sub

Sub CmdBarsEin()
   Dim iRow As Integer
   iRow = 1
   With ThisWorkbook.Worksheets("CmdBars")
      Do Until IsEmpty(.Cells(iRow, 1))
         Application.CommandBars(.Cells(iRow, 1) _
            .Value).Visible = True
         iRow = iRow + 1
      Loop
      .Columns(1).Clear
   End With
End Sub