HERBERS Excel-Forum - die Dialoge

Thema: Bestellfax über Dialog

Home
Über eine ComboBox werden Bestelldaten in ein Fax-Formul eingetragen. Die Berechnung der Preise erfolgt automatisch. Bestellfax über Dialog
  • Prozedur: UserForm_Initialize
  • Art: Ereignis
  • Modul: Klassenmodul der UserForm
  • Zweck: Artikel in ComboBox einlesen
  • Ablaufbeschreibung:
    • Variablendeklaration
    • Zeilenzähler initialisieren
    • Rahmen um das Arbeitsblatt-Objekt bilden
    • Schleife bis zur ersten leeren Zelle
    • Zellinhalt in ComboBox eintragen
    • Zeilenzähler eins hochzählen
  • Code:

    
    Private Sub UserForm_Initialize()
       Dim iRow As Integer
       iRow = 2
       With Worksheets("Artikelliste")
          Do Until IsEmpty(.Cells(iRow, 1))
             cboArtikel.AddItem .Cells(iRow, 2).Value
             iRow = iRow + 1
          Loop
       End With
       cboArtikel.ListIndex = 0
    End Sub
    
  • Prozedur: cboArtikel_Change
  • Art: Ereignis
  • Modul: Klassenmodul der UserForm
  • Zweck: Wertezuweisung an TextBoxes gemäß ComboBox-Auswahl
  • Ablaufbeschreibung:
    • Rahmen um das Arbeitsblatt-Ojekt bilden
    • 1. TextBox Wert zuweisen
    • 2. TextBox Wert zuweisen
  • Code:

    
    Private Sub cboArtikel_Change()
       With Worksheets("Artikelliste")
          TextBox1.Text = _
             .Cells(cboArtikel.ListIndex + 2, 1).Value
          TextBox2.Text = _
             .Cells(cboArtikel.ListIndex + 2, 3).Value
       End With
    End Sub
    
  • Prozedur: cmdOK_Click
  • Art: Ereignis
  • Modul: Klassenmodul der UserForm
  • Zweck: Artikel ins Fax-Formular eintragen
  • Ablaufbeschreibung:
    • Variablendeklaration
    • Zeilenindex der ersten freien Zelle in Spalte A in eine Integer-Variable einlesen
    • Daten in 4 Spalten eintragen
    • Einzelpreis mit Stückzahl multiplizieren und eintragen
  • Code:

    
    Private Sub cmdOK_Click()
       Dim iRow As Integer
       iRow = Cells(Rows.Count, 1).End(xlUp).Row + 1
       Cells(iRow, 1).Value = TextBox1.Text
       Cells(iRow, 2).Value = cboArtikel.Value
       Cells(iRow, 3).Value = TextBox3.Text
       Cells(iRow, 4).Value = TextBox2.Text
       Cells(iRow, 5).Value = _
          Cells(iRow, 3).Value * Cells(iRow, 4).Value
    End Sub