Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Listen/Datensätze

Beitrag: 2 Spalten: Einträge ermitteln, die nur in einer Spalte enthalten sind

Aufgabe
Du willst zwei Spalten vergleichen und eine Liste derjenigen Einträge (Zahlen, Texte) erhalten, die nur in der ersten Spalte enthalten sind:

       A               B               C       
1 1  5  1  
2 2  6  2  
3 3  9  3  
4 4  8  abc  
5 4  9  7  
6 6  10   
7 abc  4   
8 7  14   
9 9  13   
10 10  12   

Lösung
Spalte1: A
Spalte2: B

In C1 steht:
{=WENNFEHLER(INDEX(A:A;KKLEINSTE(WENN(A$1:A$99<>"";WENN(ZÄHLENWENN(B$1:B$99;A$1:A$99)=0;ZEILE(X$1:X$99)));ZEILE(X1)));"")}

Diese Formel runterkopieren.

Die Anzahl ergibt
{=ANZAHL2(A1:A99)-ANZAHL(VERGLEICH(A1:A99;B1:B99;0))}

Ergänzung vom 19.10.2004
Hilfsspaltenlösung bei großem Datenbestand

Für große Bereiche ist obige Formel ungeeignet, da ja jede Zelle aus Spalte A mit jeder Zelle aus Spalte B verglichen wird. Das sind bei 10.000 Zeilen 100 Millionen Vorgänge.

Schreibe in C1 (Hilfsspalte - ausblenden):
=WENN(ZÄHLENWENN(B:B;A1)=0;1;"")
und in C2:
=WENN(ODER(A2="";ZÄHLENWENN(B:B;A2)>0);"";MAX(C$1:C1)+1)
Sollen keine Doppelten aufgeführt werden, dann in C2:
=WENN(ODER(A2="";ZÄHLENWENN(B:B;A2)>0;ZÄHLENWENN(A$1:A1;A2)>0);"";MAX(C$1:C1)+1)
runterkopieren

Lückenlose Auflistung ab D1:
=INDEX(A:A;VERGLEICH(ZEILE(A1);C:C;0))
bzw. ohne Fehlermeldung, wenn keine mehr auftauchen:
=WENN(ZEILE(A1)>MAX(C:C);"";INDEX(A:A;VERGLEICH(ZEILE(A1);C:C;0)))
ab Excel 2007 natürlich mit WENNFEHLER
runterkopieren