Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Listen/Datensätze - BEITRAG: 3 Spalten nebeneinander lückenlos in eine Spalte untereinander *


Aufgabe
Der Inhalt der 3 Spalten A1 bis C20 soll ohne Leerzellen in einer Spalte untereinander dargestellt werden.

       A               B               C               D               E       
1 10    10  10  
2 20  12  20  20  
3 30    30  30  
4     24  Anna   
5   Jens    Nicole   
6     36  Patricia   
7   WF    1   
8       2   
9   Andy    3   
10 Anna      Jens  Anna  
11       WF   
12       Andy   
13       12   
14       24   
15 Nicole      36  Nicole  
16       120   
17          
18          
19          
20 Patricia    120    Patricia 


Lösung
in E1 steht
=WENN(INDEX(A:C;REST(ZEILE()-1;20)+1;(ZEILE()-1)/20+1)="";"";INDEX(A:C;REST(ZEILE()-1;20)+1;(ZEILE()-1)/20+1))
oder einfacher (Zahlen werden dann Text):
=""&INDEX(A:C;REST(ZEILE()-1;20)+1;(ZEILE()-1)/20+1)
bis E60 kopieren

in D1 steht
{=WENN(ZEILE()>ANZAHL2(A$1:C$20);"";INDEX(E:E;KKLEINSTE(WENN($E$1:$E$60<>"";ZEILE($1:$60));ZEILE())))}
bzw. ab Excel2010 (da wird auch ein Formelergebnis ="" ignoriert):
{=WENNFEHLER(INDEX(E:E;KKLEINSTE(WENN($E$1:$E$60<>"";ZEILE($1:$60));ZEILE()));"")}
bis D60 kopieren

Die Hilfsspalte E dann ausblenden.

Ergänzung vom 08.01.2008
Lösung ohne Hilfsspalte E (von neopa):
in D1 steht:
{=WENNFEHLER(INDEX(A:C;REST(KKLEINSTE(WENN(A$1:C$99<>"";ZEILE($1:$99)+SPALTE(A:C)*999);ZEILE());999);KÜRZEN(KKLEINSTE(WENN(A$1:C$99<>"";ZEILE($1:$99)+SPALTE(A:C)*999);ZEILE())/999));"")}

Erläuterung
2 nicht nebeneinander liegende Spalten: siehe Nr. 43 (Listen/Datensätze)