Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Textfunktionen

Beitrag: Alle Worte eines Satzes auflisten = Text in Spalten

Aufgabe
Der Satz steht in Zelle A1 und soll zerlegt werden.

       A       
1 Und Schreck befiel die Klapperschlangen, als ihre Klappern schlapper klangen.  
2 Und Schreck befiel die Klapperschlangen als ihre Klappern schlapper klangen  
3  
4  
5 Und  
6 Schreck  
7 befiel  
8 die  
9 Klapperschlangen  
10 als  
11 ihre  
12 Klappern  
13 schlapper  
14 klangen 

Lösung
In A2 (Hilfszelle) werden Satzzeichen und mehrfach vorkommende Leerzeichen eliminiert.
=GLÄTTEN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(A$1&" ";",";);". ";);"!";);"?";);";";);":";))

Das Ergebnis - irgendwo:
=TEIL(LINKS(" "&$A$2;FINDEN("##";WECHSELN(" "&$A$2;" ";"##";ZEILE(A2))&"##")-1);FINDEN("##";WECHSELN(" "&$A$2;" ";"##";ZEILE(A1))&"##")+1;99)
runterkopieren
tricky und einfacher von Lupo1:
=GLÄTTEN(TEIL(WECHSELN(A$2;" ";WIEDERHOLEN(" ";999));ZEILE(X1)*999-998;999))

Sollen die einzelnen Worte waagerecht (Formelersatz für Daten / Text in Spalten) aufgelistet werden:
=TEIL(LINKS(" "&$A$2;FINDEN("##";WECHSELN(" "&$A$2;" ";"##";SPALTE(B1))&"##")-1);FINDEN("##";WECHSELN(" "&$A$2;" ";"##";SPALTE(A1))&"##")+1;99)
nach rechts kopieren
bzw.
=GLÄTTEN(TEIL(WECHSELN($A2;" ";WIEDERHOLEN(" ";199));SPALTE(A1)*199-198;199))

Erläuterung
Sollen nur einzelne Worte gezielt herausgepickt werden: siehe Formel Nr. 301.