Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Summenfunktionen - BEITRAG: Als Text formatierte Zahlen mit Minuszeichen rechts summieren


Aufgabe
Du hast eine Reihe Zahlen aus einem externen Programm importiert.
Excel erkennt diese Zahlen nun als Text. Zudem steht bei negativen
Zahlen das Minuszeichen rechts. Wie werden solche "Zahlen" trotzdem
summiert ?

       A       
1 143,51-  
2 129,16  
3 377,4  
4 575,6-  
5 315,35  
6 492,77-  
7 964,11  
8 115,98-  
9 265,21  
10 928,99  
11  
12 Summe:  
13 1.652,36 

Lösung
Bereich: A1:A10

{=SUMME(WENN(ISTFEHLER((A1:A10)*1);TEIL(A1:A10;1;LÄNGE(A1:A10)-1)*-1;A1:A10*1))}

für eine einzelne Zelle:
Menu - Daten - Text in Spalten - fertig stellen
oder per Formel:
=MAX(A1;-WECHSELN(A1;"-";))
bzw. wenn alle Zahlen (auch die "normalen") Text sind:
=-WENNFEHLER(-A1;WECHSELN(A1;"-";))

Letzteres dann in die Summenfunktion eingebaut:
{=SUMME(WENN(RECHTS(A1:A10)="-";-WECHSELN(A1:A10;"-";);A1:A10))}

und mit:
{=SUMME(WENN(ISTTEXT(A1:A10);-WECHSELN(A1:A10;"-";);A1:A10))}
dürfen hinter dem Minuszeichen auch Leerzeichen stehen.