Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Excel4-Makrofunktionen

Beitrag: Ausgabe von Zell- und Objektkoordinaten

Aufgabe
Die XY-Koordinaten sowie die Breite und Höhe einer Zelle sollen ermittelt werden können.
Die Position eines Objektes innerhalb der Tabelle soll ausgegeben werden.
Lösung
Die Koordinaten der Zelle (Points) beziehen sich auf die linke obere Ecke der Zelle und beginnen in A1.
A1 hat also die Koordinaten 0;0.

Selektiere A1 (wichtig!) und wähle
Einfügen>Namen>Name festlegen/definieren

Zell-Koordinaten:

Name:Links (Koordinate der horizontalen X-Achse)
bezieh sich auf: =ZELLE.ZUORDNEN(42;A1)-ZELLE.ZUORDNEN(42;$A1)+0*JETZT()

Name:Top (Koordinate der vertikalen y-Achse)
bezieht sich auf: =ZELLE.ZUORDNEN(43;A1)-ZELLE.ZUORDNEN(43;A$1)+0*JETZT()

Zell-Höhe und -Breite:
Name:Höhe
bezieht sich auf: =ZELLE.ZUORDNEN(43;A2)-ZELLE.ZUORDNEN(43;A1)+0*JETZT()

Name:Breite
bezieht sich auf: =ZELLE.ZUORDNEN(42;B1)-ZELLE.ZUORDNEN(42;A1)+0*JETZT()

schreibe in eine Zelle:
="Diese Zelle liegt in Pos. (Points) " &links&" / "&top&" und hat die Größe (HxB) " &höhe&" / "&breite

Objekt-Koordinaten:
Schreibe in A1 den Objektnamen, z.B. "Linie1"
Selektiere B1 (wichtig!) und wähle
Einfügen>Namen>Name festlegen/definieren

Name:ObjZelle (Zelladresse, in der das Objekt liegt)
Bezieht sich auf:=OBJEKT.ZUORDNEN(4;Tabelle1!A1)&WENN(0*JETZT();"";"")

Name:ObjLinks (X-koordinate)
Bezieht sich auf:=ZELLE.ZUORDNEN(42;INDIREKT(ObjZelle;0))-ZELLE.ZUORDNEN(42;$A1)+OBJEKT.ZUORDNEN(5;A1)

Name:ObjTop (y-koordinate)
Bezieht sich auf:=ZELLE.ZUORDNEN(43;INDIREKT(ObjZelle;0))-ZELLE.ZUORDNEN(43;A$1)+OBJEKT.ZUORDNEN(6;A1)

schreibe nun in B1 =A1&" liegt in Pos. "&objlinks&" / "&objtop&" in Zelle "&objzelle
und Du erhälst die XY-Koordinaten des Objektes und in welcher Zelle es liegt.

Mit F9 aktualisieren