Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Sonstiges - BEITRAG: Auswertungen sich überlappender Bereiche


Aufgabe
In den Bereichen (im Beispiel A1:C8 und B5:D12) soll die Schnittmenge (also B5:C8) ausgewertet werden.

       A               B               C               D       
1   1,2  A  
2 10  Jens  ab  B  
3 15  10    C  
4 20    3,4  D  
5 25  WF  cd  E  
6 30  8    F  
7 35    5,6  G  
8 40    ef  H  
9 45  Boris    I  
10 50  7,8  J  
11 55    gh  K  
12 60      L  
13 65    9,1 

Lösung
=SUMME(A1:C8 B5:D12) - Summe

Zählen:
{=ANZAHL2(A1:C8 B5:D12&1)} - alle
=ANZAHL2(A1:C8 B5:D12) - gefüllte
=ANZAHL(A1:C8 B5:D12) - mit Zahlen gefüllte
=ANZAHLLEEREZELLEN(A1:C8 B5:D12) - Leerzellen

=MAX(A1:C8 B5:D12) - Maximum
=MIN(A1:C8 B5:D12) - Minimum


Erläuterung
Funktioniert ebenso bei benannten Bereichen und bei mehr als 2.
Der "Operator" zwischen den einzelnen Bereichen ist das Leerzeichen.


Vereinigungsmenge:
Angenommen Du hast zwei Bereiche, z.B. A1:D4 und C3:E5. Nun willst Du die Summe beider Bereiche ermitteln.
=SUMME(A1:D4;C3:E5) hat den Nachteil, dass die Schnittmenge C3:D4 doppelt berechnet wird. Siehe folgende Beispiele, um allgemeingültig die richtige Vereinigungsmenge, ohne Doppelzählung, zu berechnen:

Summe:{=SUMME(Bereich1;Bereich2;-Bereich1 Bereich2)} (In XL2003 muß man mit strg+Umschalt+Enter abschließen, in XL2007 nicht!)
Anzahl:=ANZAHL(Bereich1;Bereich2)-ANZAHL(Bereich1 Bereich2)
Mittelwert:{=SUMME(Bereich1;Bereich2;-Bereich1 Bereich2)/(ANZAHL(Bereich1;Bereich2)-ANZAHL(Bereich1 Bereich2))}
Zählenwenn(Suchkriterium):=ZÄHLENWENN(Bereich1;Suchkriterium)+ZÄHLENWENN(Bereich2;Suchkriterium)-ZÄHLENWENN(Bereich1 Bereich2;Suchkriterium)