Bei mehrfach auftretenden Werten die nächste Rangstelle anzeigen

Gruppe: Statistik

Beitrag: Bei mehrfach auftretenden Werten die nächste Rangstelle anzeigen

Aufgabe

In der Funktion RANG wird bei einem doppelt auftretenden Wert die Rangstelle wiederholt und die nächste übersprungen.
Es soll bei mehrfach auftretenden Werten jeweils die nächste Rangstelle angezeigt werden.

Lösung

	A	B	C	D	E	F	G
1	7	6	6		7	7	7
2	11	3	3		8	8	10
3	12	2	2		11	11	11
4	3	10	10		2	2	3
5	3	10	11		2	3	2
6	6	7	7		6	6	6
7	4	9	9		4	4	4
8	15	1	1		12	12	12
9	11	3	4		8	9	9
10	2	12	12		1	1	1
11	11	3	5		8	10	8
12	5	8	8		5	5	5

Leerzellen dürfen keine vorkommen.

In Spalte B steht die "normale" Folge von RANG.

In C1 steht:

=RANG(A1;A$1:A$100)

In C2 steht:

{=RANG(A2;A$1:A$100)+SUMME((RANG(A$1:A1;A$1:A$100)=RANG(A2;A$1:A$100))*1)}

und runterkopieren

Das ganze funktioniert auch absteigend mit der Reihenfolge ...;-1):
In Spalte E steht die "normale" Folge von RANG mit ;-1).

In F1 steht:

=RANG(A1;A$1:A$100;-1)

In F2 steht:

{=RANG(A2;A$1:A$100;-1)+SUMME((RANG(A$1:A1;A$1:A$100)=RANG(A2;A$1:A$100))*1)}

und runterkopieren

Hier werden Doppler aber aufsteigend rangiert; - soll dieses vermieden werden:
in G1 steht:

{=RANG(A1;A$1:A$100;-1)+WENN(A2="";0;SUMME((RANG(A2:INDIREKT("A"&ANZAHL(A:A));A$1:A$100;-1)=RANG(A1;A$1:A$100;-1))*1))}

und runterkopieren

Verkürzungen vom 28.07.2005
In C1 steht:

=RANG(A1;A:A)+ZÄHLENWENN(A$1:A1;A1)-1

In F1 steht:

=RANG(A1;A:A;-1)+ZÄHLENWENN(A$1:A1;A1)-1

In G1 steht:

=RANG(A1;A:A;-1)+ZÄHLENWENN(A1:A$100;A1)-1

Erläuterung

WF:
Im Gegensatz zu KGRöSSTE funktioniert das nicht:

{=RANG(A1+ZEILE()/10000;A1:A100+ZEILE(1:100)/10000)}

warum?

Das Portal zum Thema Excel-Formeln