Berechnung des Barwertes bei steigenden Zahlungen + Entnahmeplan

Gruppe: Finanzmathematik

Beitrag: Berechnung des Barwertes bei steigenden Zahlungen + Entnahmeplan

Aufgabe

Die Funktion BW funktioniert nur bei konstanten Zahlungen. Wie kann man einen Barwert ermitteln, wenn die Zahlungen jedes Jahr prozentual steigen (Index) ?

		A
1		6,0%
2		1,5%
3		1.000,00
4		10
5		0
6
7		7.821,33

Lösung

A1: Abzinsungssatz
A2: Jährliche Steigerung in Prozent
A3: Anfangszahlung
A4: Laufzeit
A5: 0 (nachschüssig) oder 1 (vorschüssig)

Mathematische Lösung:

=A3*(1-((1+A2-0,1^9)/(1+A1))^A4)/(A1-A2+0,1^9)*(1+(A5=1)*A1)

bzw.

=A3*(1-((1+A2)/(1+A1))^A4)/(A1-A2)*(1+(A5=1)*A1)

Lösung mit Array-Formel:

{=NBW(A1;A3*(1+A2)^(ZEILE(INDIREKT("1:"&A4))-1))*(1+(A5=1)*A1)}

Ergänzung vom 01.12.2006
Und nun das ganze umgekehrt: Du willst wissen, wie hoch die Eingangszahlung sein muss, um einen vorgegebenen Barwert zu erreichen (Entnahmeplan).
Das funktioniert natürlich mit obigen Formeln per Zielwertsuche aber auch direkt.
In A3 steht jetzt der gewünschte Barwert - z.B. 100.000,-
Alle anderen obigen Parameter bleiben für dieses Beispiel unverändert.

=A3/((1-((1+A2-0,1^9)/(1+A1))^A4)/(A1-A2+0,1^9)*(1+(A5=1)*A1))

bzw.

=A3/((1-((1+A2)/(1+A1))^A4)/(A1-A2)*(1+(A5=1)*A1))

Ergebnis: 12.785,54

Erläuterung

0,1^9 in der jeweils ersten Formel dient lediglich dazu #DIV/0 bei identischem Abzinsungssatz und Indexprozentsatz zu vermeiden (dürfte ja wohl nie vorkommen).

Das Portal zum Thema Excel-Formeln