Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Datum/Zeit - BEITRAG: Bestimmung des Datums des ersten Samstages in einem Monat


Aufgabe
Es soll ab einem beliebigem Datum der x_te Wochentag ermittelt werden, z.B. der erste Samstag.

       A               B               C               D               E       
1 Datum    Wochentag  X_ter  Ergebnis  
2 05.01.2002    10  12.03.2002  
3 01.01.2002    07.01.2002  
4 01.04.1963    06.04.1963  
5 15.05.1999    26.05.1999 

Lösung
Das Ausgangsdatum steht in Spalte A (beliebiges Datum des gewünschten Monats
Wochentag(1=Montag bis 7=Sonntag) steht in C
X_ter Tag steht in D
Ergebnis steht in E:
=WENN(WOCHENTAG(A1;2)>C1;A1+7*D1+C1-WOCHENTAG(A1;2);A1+C1+7*(D1-1)-WOCHENTAG(A1;2))

Klasse vereinfacht von Peter Dorigo:
=A1-1-WOCHENTAG(A1-C1;3)+7*D1
ohne die Funktion Wochentag (Josef Burch)
=A1-REST(A1-2-C1;7)+7*D1-1

Soll jeweils der letzte Wochentag aus Spalte C im Monat aus Spalte A angezeigt werden (Idee von Götz Alles):
=DATUM(JAHR(A1);MONAT(A1)+1;0)-(WOCHENTAG(DATUM(JAHR(A1);MONAT(A1)+1;0);2)-C1+(WOCHENTAG(DATUM(JAHR(A1);MONAT(A1)+1;0);2) < C1)*7)

verkürzt von Ernst-Albrecht Borgener:
=DATUM(JAHR(A1);MONAT(A1)+1;0)-WOCHENTAG(DATUM(JAHR(A1);MONAT(A1)+1;1-C1);3)
ohne die Funktion Wochentag (Josef Burch)
=DATUM(JAHR(A1);MONAT(A1)+1;-REST(DATUM(JAHR(A1);MONAT(A1)+1;-1)-C1;7))

Ergänzung vom 07.10.2012: alle Wochentage eines Monats auflisten
Datum in A1 - gewünschter Wochentag in C1 (wie oben)
A2 ist leer (Entf)
in A3 steht:
=WENN(UND(NICHT(ISTLEER(A2));A2=0);0;(A$1-TAG(A$1)-REST(A$1-TAG(A$1)-1-C$1;7)+7*ZEILE(Z1))*(TAG(A2+7)>TAG(A2)))
bis A7 runterkopieren
A3 bis A7 benutzerdefiniert formatieren mit TTTT TT.MM.JJJJ;;