Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Listen/Datensätze - BEITRAG: Eine Liste per Formel sortieren *


Aufgabe
Eine Liste soll mit einer Formel in sortierter Reihenfolge ausgegeben werden.

       A               B               C       
1 januar  april  
2 februar  august  
3 märz  februar  
4 april  januar  
5 mai  juli  
6 juni  juni  
7 juli  mai  
8 august  märz  
9 september  oktober  
10 oktober  september 

Lösung
Liste steht in Spalte A von A1 bis A10

Alternative 1 (mit Hilfsspalte B):
in B1 steht
=SUMMENPRODUKT((A$1:A$10 < A1)+(A1="")*1000)
kopieren bis B10

in C1 steht:
=INDEX(A:A;VERGLEICH(KKLEINSTE(B$1:B$10;ZEILE());B$1:B$10;0))
kopieren bis C10

Alternative 2 ohne Hilfsspalte:
(funktioniert nur bei Text und ohne Leerzellen)
in B1 steht:
{=INDEX(A$1:A$10;VERGLEICH(KKLEINSTE(ZÄHLENWENN(A$1:A$10;"<"&A$1:A$10);ZEILEN($1:1));ZÄHLENWENN(A$1:A$10;"<"&A$1:A$10);0))}
kopieren bis B10

10.08.2011 - Text/Zahlen gemischt mit Leerzellen und deshalb auch ohne Bereichsbeschränkung (Josef Burch + Franz Pölt):
{=INDEX(A:A;VERGLEICH(KGRÖSSTE(ZÄHLENWENN(A$1:A$99;">="&A$1:A$99)+99*ISTZAHL(A$1:A$99);ZEILEN($1:1));ZÄHLENWENN(A$1:A$99;">="&A$1:A$99)+99*ISTZAHL(A$1:A$99);0))&""}