Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Mathematische Funktionen

Beitrag: Einen Kreis aus Drei Punkten berechnen *

Aufgabe
Aus drei Punkten im XY-Koordinatensystem soll der Kreis berechnet werden, der durch diese drei Punkte läuft.
Autor: Klaus Kühnlein



Lösung
Die X-Werte der drei Punkte stehen in
A1:A3, die Y-Werte in B1:B3

C1: =A1^2+B1^2
D1: =A1
E1: =B1

Kopiere C1 bis E1 bis C3:E3 nach unten.

Formel für xM in G1:
=-INDEX(MMULT(MINV(C1:E3);{1;1;1});2)/(MMULT(MINV(C1:E3);{1;1;1}))/2

Formel für yM in H1:
=-INDEX(MMULT(MINV(C1:E3);{1;1;1});3)/(MMULT(MINV(C1:E3);{1;1;1}))/2

Formel für Radius in F1;
=WURZEL((A1-G1)^2+(B1-H1)^2)


Erläuterung
Für die Darstellung im Diagramm fehlt noch:
G2: =G1
H2: =H1+F1
(für den Radius)

F5:F17 0-360 Grad
G5:=+SIN(BOGENMASS(F5))*$F$1+$G$1
H5:=COS(BOGENMASS(F5))*$F$1+$H$1
kopieren bis G17 und H17
(für den gestrichelten Kreis)

Erstellung des Diagramms:

Wähle den Diagrammtyp Punkt(XY)-Diagramm.

Das Diagramm enthält folgende Datenreihen
1. Die Punkte mit den x-Werten aus A1:A3 und den y-Werten aus B1:B3
2. Der Kreis mit den x-Werten aus G5:G17 und den y-Werten aus H5:H17
3. Der Radius mit den x-Werten aus G1:G2 und den y-Werten aus H1:H2