Das Portal zum Thema Excel-Formeln

Von einem Datum in Zelle A1 soll das Quartal ermittelt werden.

Jan - Mrz = 1. Quartal
Apr - Jun = 2. Quartal
Jul - Sep = 3. Quartal
Okt - Dez = 4. Quartal

=AUFRUNDEN(MONAT(A1)/3;0)&". Quartal"
oder

=MONAT(MONAT(A1)&0)&". Quartal"

Der Quartalserste ist: =DATUM(JAHR(A1);MONAT(A1)-REST(MONAT(A1)-1;3);1)
Der Quartalsletzte: =DATUM(JAHR(A1);MONAT(A1)+REST(3-MONAT(A1);3)+1;)

Soll das erste Quartal mit dem April beginnen (Bilanzstichtag 31.03.) dann:

=REST(AUFRUNDEN(MONAT(A1)/3;0)+2;4)+1&". Quartal"

oder mit obiger Formel:

=WAHL(MONAT(MONAT(A1)&0);2;3;4;1)&". Quartal"

Bilanzstichtag 30.06.

=REST(AUFRUNDEN(MONAT(A1)/3;0)+1;4)+1&". Quartal"

=WAHL(MONAT(MONAT(A1)&0);3;4;1;2)&". Quartal"

Bilanzstichtag 30.09.

=REST(AUFRUNDEN(MONAT(A1)/3;0);4)+1&". Quartal"

=WAHL(MONAT(MONAT(A1)&0);4;1;2;3)&". Quartal"

Bilanzstichtag per beliebigem Monatsende von Roger Herden:
Monat (Zahl) steht in B1

=AUFRUNDEN(((MONAT(A1)+(MONAT(A1)<=B1)*12)-B1)/3;0)&". Quartal"

Halbjahresanfang und Halbjahresende sind übrigens:

=DATUM(JAHR(A1);1+(MONAT(A1)-6>0)*6;1)

und

=DATUM(JAHR(A1);(MONAT(A1)-6>0)*6+7;0)