Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Datum/Zeit - BEITRAG: Ersatz der Funktion NETTOARBEITSTAGE


Aufgabe
Die Funktion NETTOARBEITSTAGE ist ein Add-In.
Gibt man eine Datei weiter und auf dem anderen Rechner ist das Add-In "Analysefunktionen" nicht geladen, erhält der Anwender Fehlermeldungen. Die Funktion soll vermieden werden.

       A       
1 Mi, 26.09.01  
2 Fr, 28.09.01  
3 Ergebnis ist 3  
4  
5  
6 Fr, 28.09.01  
7 Mo, 01.10.01  
8 Ergebnis ist 2 
(jeder angebrochene Arbeitstag zählt voll, die Wochenenden werden herausgerechnet)

Lösung
Das Anfangsdatum steht in A1, das Enddatum in A2.
Das Enddatum darf nicht vor dem Anfangsdatum liegen.

=A2+1-A1-GANZZAHL((WOCHENTAG(A1;2)+A2-A1)/7)-GANZZAHL((WOCHENTAG(A1;1)+A2-A1)/7)
(Ohne Abzug der zweiten GANZZAHL erhält man die Anzahl der Werktage.)
bzw:
=SUMMENPRODUKT((WOCHENTAG(ZEILE(INDIREKT(A1&":"&A2));2)<6)*1)
bzw. mit INDEX statt INDIREKT:
=SUMMENPRODUKT((WOCHENTAG(ZEILE(INDEX(A:A;A1):INDEX(A:A;A2));2)<6)*1)
(Werktage: hinten <7)
Diese Lösung berücksichtigt KEINE Feiertage!

Mit der Berücksichtigung von Feiertagen (für die Errechnung von beweglichen Feiertagen siehe unsere Formeln Nr. 3 und 299):
Anfangsdatum: A1
Enddatum: A2
Feiertage: C1:C25
=SUMMENPRODUKT((WOCHENTAG(ZEILE(INDIREKT(A1&":"&A2));2)<6)*1)-SUMMENPRODUKT((C1:C25>=A1)*(C1:C25<=A2)*(WOCHENTAG(C1:C25;2)<6))

Sollen Feiertage in der Liste nur halb (z.B. Heiligabend) oder gar nicht berücksichtigt werden, endet die Formel mit:
.....<6)*(D1:D25))
In D1 bis D25 steht dann entweder 1 (volle Berücksichtigung) oder 0,5 (halbe Berücksichtigung) oder leer (keine Berücksichtigung).

Ergänzung
in A1 steht irgendein Datum und es sollen die Arbeitstage dieses Monats errechnet werden:
=SUMMENPRODUKT((WOCHENTAG(DATUM(JAHR(A1);MONAT(A1);ZEILE(INDIREKT("1:"&TAG(DATUM(JAHR(A1);MONAT(A1)+1;)))));2)<6)*1)
mit Feiertagen:
-SUMMENPRODUKT((C1:C25>=DATUM(JAHR(A1);MONAT(A1);1))*(C1:C25<=DATUM(JAHR(A1);MONAT(A1)+1;))*(WOCHENTAG(C1:C25;2)<6))
dranhängen


Erläuterung
Hinweis von Manfred Flohr
Fällt Christi Himmelfahrt auf den 1. Mai, zieht der Feiertags-Subtrahend einen Tag zuviel ab. Das war 2008 der Fall. In diesem Jahr muss man also den fehlenden Arbeitstag wieder dazuzählen oder vorher einen der beiden Feiertage aus der Liste C1:C25 löschen. Jetzt bleibt zunächst mal bis 2160 alles ruhig ...
Wer denkt schon daran, in einer berechneten Feiertagsliste (Siehe Formel Nr.3) Duplikate zu eliminieren?! Diese Katastrophe ist aber äußerst selten.