Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Tabellennavigation - BEITRAG: Ganze Tabelle (A2 bis IV65536) nach Suchbegriff durchsuchen


Aufgabe
Das ganze Arbeitsblatt soll nach einem Begriff durchsucht werden.
Die Koordinaten (Zeilen- und Spaltennummer) des ersten gefunden Suchbegriffes sollen ermittelt werden.

       A               B               C               D       
1    
2        
3        
4       x  
5     x   

Lösung
Suchbegriff: "x"
Es wird spaltenweise durchsucht, also C5 wird vor D4 gefunden.

In A1 steht die Spalte:
{=MIN(WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN(A2:A65536;;SPALTE(A1:IQ1)-1;;);"x")>0;SPALTE(A1:IQ1)))}

in B1 steht die Zeile:
=VERGLEICH("x";BEREICH.VERSCHIEBEN(A:A;;A1-1;;);0)

Alternativ:
Die folgende Formel in B1 gibt die Adresse in A1-Schreibweise zurück:

{=ADRESSE(VERGLEICH("x";BEREICH.VERSCHIEBEN(A:A;;MIN(WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN(A2:A65536;;SPALTE(A1:IQ1)-1;;);"x")>0;SPALTE(A1:IQ1)))-1;;);0);MIN(WENN(ZÄHLENWENN(BEREICH.VERSCHIEBEN(A2:A65536;;SPALTE(A1:IQ1)-1;;);"x")>0;SPALTE(A1:IQ1))))}

Variante:
Für einen überschaubaren Bereich - hier A2:F100 - langen (es wird jetzt zeilenweise durchsucht):
Zeile in B1:
{=MIN(WENN(A2:F100="x";ZEILE(2:100)))}
Spalte:
=VERGLEICH("x";INDEX(A:F;B1;0);0)
Adresse:
{=ADRESSE(MIN(WENN(A2:F100="x";ZEILE(2:100)));VERGLEICH("x";INDEX(A:F;MIN(WENN(A2:F100="x";ZEILE(2:100)));0);0))}

Ist sicher, daß der Suchbegriff NUR EINMAL vorkommt, langt:
{=ADRESSE(MAX((A2:F100="x")*ZEILE(2:100));MAX((A2:F100="x")*SPALTE(A:F)))}
ohne {}:
=ADRESSE(SUMMENPRODUKT((A2:F100="x")*ZEILE(2:100));SUMMENPRODUKT((A2:F100="x")*SPALTE(A:F)))

(Bei obigem Beispiel erhielte man die falsche Zelle D5.)


Erläuterung
Will man mit der Variante die gesamte mögliche Tabellendimension abgrasen; - also: A2:IV65536 geht der Rechner in die Kniee, stürzt ab, bootet neu oder meldet "zu wenig Arbeitsspeicher".

WF: NICHT AUSPROBIEREN !!! (Ihr macht's ja doch.)