Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Statistik

Beitrag: Häufigsten Eintrag (Modalwert) in einer oder mehreren Spalten ermitteln *

Aufgabe
Du willst wissen, welcher Eintrag am häufigsten vorkommt.
Dafür gibt es die Funktion =MODALWERT(A1:A99) bzw. =MODALWERT(A1:C99)
Diese funktioniert aber nur für Zahlen.
Für Texte:

       A               B       
1  
2  
3  
4 x   
5  
6  
7 x   
8  
9 x   
10  
11    
12 Ergebnis:  x (3 mal) 

Lösung
Suchspalte: A

{=INDEX(A:A;VERGLEICH(MAX(ZÄHLENWENN(A1:A99;A1:A99));ZÄHLENWENN(A1:A99;A1:A99);0))}
Variante mit MODALWERT von neopa:
{=INDEX(A:A;MODALWERT(WENN(A1:A99<>"";VERGLEICH(A1:A99;A1:A99;0))))}
dito bei gefilterter Tabelle:
{=INDEX(A:A;MODALWERT(WENN(TEILERGEBNIS(3;INDIREKT("A"&ZEILE(1:99)));VERGLEICH(A1:A99;A1:A99;0))))}

Suchspalten A:C

{=INDIREKT(ADRESSE(MIN(WENN(ZÄHLENWENN(A1:C99;A1:C99)=MAX(ZÄHLENWENN(A1:C99;A1:C99));ZEILE(1:99)));REST(MIN(WENN(ZÄHLENWENN(A1:C99;A1:C99)=MAX(ZÄHLENWENN(A1:C99;A1:C99));ZEILE(1:99)+SPALTE(A:C)/1000));1)*1000))}

Wer lieber INDEX statt INDIREKT benutzt:
{=INDEX(A:C;MIN(WENN(ZÄHLENWENN(A1:C99;A1:C99)=MAX(ZÄHLENWENN(A1:C99;A1:C99));ZEILE(1:99)));REST(MIN(WENN(ZÄHLENWENN(A1:C99;A1:C99)=MAX(ZÄHLENWENN(A1:C99;A1:C99));ZEILE(1:99)+SPALTE(A:C)/1000));1)*1000)}

Erläuterung
Funktionieren alle natürlich auch mit Zahlen.