Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Datum/Zeit - BEITRAG: Immer das Datum des nächsten Freitags anzeigen *


Aufgabe
Ausgehend von einem vorgegebenen Datum soll immer der nächste Freitag angezeigt werden.

Lösung
Datum steht in A1.

=A1+(WOCHENTAG(A1;2)>5)*7+(5-WOCHENTAG(A1;2))
bzw. ohne die Funktion WOCHENTAG:
=A1+(REST(A1-2;7)+1>5)*7+4-REST(A1-2;7)
Ist das Datum in A1 ein Freitag und soll dann das Datum von einer Woche später angezeigt werden, >=5 eingeben.
Für andere Wochentage, die 5 (zweimal) ersetzen durch 1 (Montag) bis 7 (Sonntag).

Absolut banal und darum klasse von Bosko Biati:
=A1+6-REST(A1;7)
bzw. ausgehend vom Freitag + 1 Woche:
=A1+7-REST(A1+1;7)


Ergänzung von Ernst-Albrecht Borgener:

Mit dieser Formel kann man das Datum des nächsten oder übernächsten oder dritten, vierten, fünften usw. Wochentag bestimmen.

In A1 steht das Datum

in B1 steht eine Zahl zwischen 1 und 7 die den gesuchten Wochentag repräsentiert.
Für Freitag = 1; Donnerstag = 2 ... Samstag = 7 (es geht also rückwärts)

In C1 steht eine Zahl die angibt ob der nächste, übernächste usw. Wochentag gesucht wird
Für den nächsten steht eine 1 für den übernächsten eine 2 usw.
(Funktioniert auch rückwärts: 0 = letzter; -1 = vorletzter usw.)

Die Formel lautet dann

=A1+7*C1-REST(A1+B1;7)

Ein Beispiel:
In A1 steht der 13.02.2004 (ein Freitag )
In B1 steht eine 6 (Ich suche also einen Sonntag)
In C1 steht eine 2 (Ich suche also den übernächsten Sonntag)
Die Formel gibt dann das Datum 22.02.2004 aus: den zweiten Sonntag nach dem 13.02.2004.

Steht in B1 nicht die Wochentagszahl sondern ausgeschrieben Sonntag - dann:
=A1+7*C1-REST(A1+SUCHEN(LINKS(B1;2);"-frdomidimososa")/2;7)