Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Bedingte Formatierung - BEITRAG: Ist der kommende Geburtstag ein runder?


Aufgabe
Es sollen die Personen hervorgehoben werden, deren kommender Geburtstag ein runder ist.
Bis 60 in 10-Jahresschritten / danach in 5-Jahresschritten.
Alternativ sollen nur die runden Geburtstage berücksichtigt werden, die noch in's aktuelle Jahr fallen.

       A               B               C       
1 Annna  29.03.1982  22  
2 Angelika  15.05.1945  59  
3 Bernd  01.08.1929  74  
4 Estelle  07.01.1950  54  
5 Hannes  05.01.1955  49  
6 Hans  24.02.1940  64  
7 Jens  09.06.1972  31  
8 Klaus  06.09.1944  59  
9 Natalie  05.06.1980  23  
10 Patrizia  09.03.1975  29  
11 Peter  09.06.1972  31  
12 Ulla  05.06.1980  23  
13 Ulli  23.10.1982  21  
14 Uwe  09.06.1994  9  
15 Walter  24.02.1949  55 

HEUTE() war für obiges Beispiel der 26.05.2004


Lösung
ohne das aktuelle Alter in Spalte C:
Markiere den Tabellenbereich A1 bis A??
Wähle Format>Bedingte Formatierung
Formel ist:
=ODER(REST(DATEDIF(B1;HEUTE();"y");10)=9;(DATEDIF(B1;HEUTE();"y")>60)*REST(DATEDIF(B1;HEUTE();"y");10)=4)
bzw. im aktuellen Jahr
=(ODER(REST(DATEDIF(B1;HEUTE();"y");10)=9;(DATEDIF(B1;HEUTE();"y")>60)*REST(DATEDIF(B1;HEUTE();"y");10)=4))*((MONAT(HEUTE())+TAG(HEUTE())/50)<=MONAT(B1)+TAG(B1)/50)
Format...dann im Reiter Schrift die Farbe und Stärke auswählen

Steht in Spalte C das aktuelle Alter mit:
=DATEDIF(B1;HEUTE();"y")
lauten die Formeln:
=ODER(REST(C1;10)=9;(C1>60)*REST(C1;10)=4)
bzw.
=(ODER(REST(C1;10)=9;(C1>60)*REST(C1;10)=4))*((MONAT(HEUTE())+TAG(HEUTE())/50)<=MONAT(B1)+TAG(B1)/50)