Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Finanzmathematik

Beitrag: Kapitalverzinsung bei steigenden Zinssätzen

Aufgabe
Ein Anfangskapital soll über eine bestimmte Anzahl Perioden verzinst werden, wobei eine jährliche Steigung des Zinssatzes unterstellt wird.

       A               B       
1 1.000,00  Barwert  
2 5%  Anfangszins  
3 10  Perioden  
4 0,2%  Zinsanstieg  
5    
6 1.773,76  Endwert 

Lösung
In A1 steht das Anfangskapital (Barwert)
in A2 steht der Zinssatz in der ersten Periode
in A3 steht die Anzahl Perioden
in A4 steht die Zinssatzsteigung in den Folgeperioden.

Das Endkapital beträgt bei linearer Zinssatzsteigerung
{=PRODUKT(A2+1+(A4*(ZEILE(INDIREKT("1:"&A3))-1)))*A1}

neu
erfolgt die Zinssatzsteigerung (in A4) dynamisch vom Ursprungszinssatz
=SUMMENPRODUKT(A2*(1+A4)^(ZEILE(INDIREKT("1:"&A3))-1))*A1+A1

Periodische Zahlungen, Ergänzung 14.01.2005:
Wenn die Zahlung während der Laufzeit jedes Jahr erfolgt, lautet der Barwert
{=SUMME(A1/(1+A2+A4*(ZEILE(INDIREKT("1:"&A3))-1))^(ZEILE(INDIREKT("1:"&A3))-A5))}
und der Endwert
{=SUMME(A1*(1+A2+A4*(ZEILE(INDIREKT("1:"&A3))-1))^(A3+1-ZEILE(INDIREKT("1:"&A3))-(A5=0)*1))}
In A5 steht die Fälligkeit der Zahlung (0 oder 1).
Bei konstanten Zinsen, also A4=0, entspricht das Ergebnis den Funktionen BW bzw. ZW.

Erläuterung
Bei der Ergänzung wird eine lineare Zinssteigung unterstellt.
Der Zinssatz in Periode 4 z.B. ist A2+3*A4 und nicht A2*(1+A4)^3


Übrigens, für eine Berechnung des Endkapitals bei variierenden Zinssätzen
gibt es die ziemlich überflüssige Add-in-Funktion ZW2(Kapital;Zinsen).

Sie berechnet einen Endwert wie folgt:
=ZW2(1000;{0,05;0,06;0,07})=1.190,91

das geht aber auch genauso mit
=PRODUKT(1+{0,05;0,06;0,07})*1000=1.190,91