Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Tabellennavigation - BEITRAG: Letzter Text in einer Zeile oder Spalte


Aufgabe
Wie kann man den letzten Text bzw. die Position des letzten Textes in einer Zeile oder Spalte ermitteln ?

       A               B               C               D               E               F       
1   e  5  
2          
3          
4          
5          
6            
7 x           
8          

Lösung
Spalte A bzw. Zeile 1

Spalte des letzten Textes einer Zeile:
{=MAX(ISTTEXT(1:1)*SPALTE(1:1))}
entsprechender Eintrag:
{=INDEX(1:1;MAX(ISTTEXT(1:1)*SPALTE(1:1)))}

Zeile des letzten Textes einer Spalte:
{=MAX(ISTTEXT(A1:A1000)*ZEILE(1:1000))}
entsprechender Eintrag:
{=INDEX(A:A;MAX(ISTTEXT(A1:A1000)*ZEILE(1:1000)))}

ohne Array - ausgetüftelt von Holger Voß
=VERGLEICH("";1:1;-1)
sowie
=VERGLEICH("";A:A;-1)
Und für den Zellinhalt dann natürlich den INDEX drumrumgerankt.

oder:
=VERWEIS(2;1/ISTTEXT(A1:A999);ZEILE(A1:A999))
=VERWEIS(2;1/ISTTEXT(A1:A999);A:A)

oder
=VERWEIS(WIEDERHOLEN("z";255);A:A)
Beate Schmitz

Erläuterung
Die VERGLEICH-Formel ist abartig, da sie ja eigentlich nicht funktionieren darf!

Für den Vergleichstyp -1 In der Funktion VERGLEICH schreibt Microsoft:
Ist Vergleichstyp gleich -1, liefert VERGLEICH den kleinsten Wert, der größer gleich Suchkriterium ist. Die Elemente der Suchmatrix müssen in absteigender Reihenfolge angeordnet sein: WAHR, FALSCH, Z-A,...2, 1, 0, -1, -2,... usw.
Die Anordnung ist hier wurscht !?

Noch skurriler ist es bei der letzten Zahl (Formel Nr. 50)

Anmerkung 04.08.04:

=VERGLEICH("";1:1;-1)
versagt, wenn im Bereich eine Zelle mit dem Formelergebnis ="" enthalten ist. Bei Wenn-Formeln ist das häufig der Fall z.B. =WENN(X1>1000;"zu viel";"")