Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Mathematische Funktionen - BEITRAG: Lösung eines linearen Gleichungssystems


Aufgabe
Ein lineares Gleichungssystem beliebigen Grades soll gelöst werden.

       A               B               C               D               E               F               G               H               I               J       
1 11  -5  -2  2  
2 6,5  -1  -2  -1  -1  -4  
3 -13  -10  -3  -1  10  -1  -2  
4 0  20  -1  -1  -1  -5  
5 18  0  
6 4  -1  -1  -1  -1  -1  -2  10  
7 -18,5  -3  -2  1  
8 33  0  
9 111  9  
10                    
11 Grad:  9         
12 Lösung:  2  -4  5  1  11  3  1,5  -1  2,5 

Lösung
Mit der Kombination aus MTRANS MMULT MINV (transponierte Matrix / Matrizenprodukt / Kehrmatrix) ist eine sehr kurze Lösung möglich.
Die entsprechende Array-Formel muss aber für jeden Grad neu kreiert werden.

Folgende Formel beschreibt die Lösung eines Gleichungssystems vom Grade 9:

Das Gleichungssystem mit den 9 Unbekannten steht in A1 bis J9
In A1 bis A9 sind die Ergebnisse der 9 Gleichungen
In B1 bis J9 die Wertigkeiten der 9 Unbekannten B C D E F G H I J

Markiere 9 Zellen nebeneinander (B13:J13); - also GLEICHZEITIG: 9 Zellen nebeneinander markieren
und gib dann folgende Array-Formel ein:
{=MTRANS(MMULT(MINV(B1:J9);A1:A9))}

Die Ergebnisse für die 9 Unbekannten stehen dann in diesen 9 Zellen.

Nochmal: NICHT die Formel KOPIEREN; - sondern 9 Zellen markieren und dann die Formel eingeben !

Man kann den Grad aber auch flexibilisieren (bis max 9; - einzutragen in B11):

Schreibe in B13 (KEINE ARRAY-FORMEL !)
=WENN(SPALTE()-1>$B$11;"";INDEX(MTRANS(MMULT(MINV(BEREICH.VERSCHIEBEN($B$1;;;$B$11;$B$11));BEREICH.VERSCHIEBEN($A$1;;;$B$11)));SPALTE()-1))
und kopiere dies bis J13.

Vereinfachung (ohne MTRANS, kein Array)
Schreibe in B13:
=INDEX(MMULT(MINV($B$1:$J$9);$A$1:$A$9);SPALTE(A1))

bzw. dynamisch (ohne Beschränkung):
=WENN(SPALTE(A1)>$B$11;"";INDEX(MMULT(MINV($B$1:INDIREKT(ADRESSE($B$11;$B$11+1)));$A$1:INDIREKT("A"&$B$11));SPALTE(A1)))

Jeweils nach rechts kopieren.
Erläuterung
Alternative
Die Ergebnisse der ersten Formel erhältst Du auch mit RGP.

Markiere B13:J13 und gebe sie als zusammenhängende Matrixformel ein.
{=RGP(A1:A9;B1:J9;0;0)}
Damit erhältst Du die 9 Unbekannten. Allerdings in umgekehrter Reihenfolge!

Den Zusammenhang zwischen den Funktionen RGP und MINV/MMULT beschreiben wir in unserem Buch: "Excel das Zauberbuch".