Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Statistik - BEITRAG: Minimum / Mittelwert ohne Nullen aber ohne Arrayformel


Aufgabe
In einer Spalte soll das Minimum / der Mittelwert ohne Berücksichtigung vorkommender Nullen bestimmt werden. Das erledigen die Array-Formeln:

{=MIN(WENN(A1:A1000;A1:A1000))}
sowie
{=MITTELWERT(WENN(A1:A1000;A1:A1000))}

Wie funktioniert das ohne Array-Formeln ?

Lösung
Minimum:
=KKLEINSTE(A1:A1000;ZÄHLENWENN(A1:A1000;0)+1)
bzw.; - da kein Array, werden auch komplette Spalten akzeptiert:
=KKLEINSTE(A:A;ZÄHLENWENN(A:A;0)+1)

Mittelwert:
=SUMME(A:A)/ZÄHLENWENN(A:A;">0")

Obige Formeln gelten nur für positive Zahlen.

Mit negativen Zahlen:
=WENN(MIN(A:A)<0;MIN(A:A);KKLEINSTE(A:A;ZÄHLENWENN(A:A;0)+1))
sowie:
=SUMME(A:A)/(ZÄHLENWENN(A:A;">0")+ZÄHLENWENN(A:A;"<0"))
bzw.
=SUMME(A:A)/SUMME(ZÄHLENWENN(A:A;{">0"."<0"}))

Bei nicht zusammenhängen Zellen funktioniert das wie folgt:
=MIN(WENN(N(INDIREKT({"A4";"B1";"C3";"D2";"E2"}));N(INDIREKT({"A4";"B1";"C3";"D2";"E2"}))))
sowie
=MITTELWERT(WENN(N(INDIREKT({"A4";"B1";"C3";"D2";"E2"}));N(INDIREKT({"A4";"B1";"C3";"D2";"E2"}))))
Auch das sind seltsamerweise keine Arrayformeln !?


Erläuterung
ein Phänomen (bug)?
warum =SUMME(A:A)/(ZÄHLENWENN(A:A;">0")+ZÄHLENWENN(A:A;"<0"))
=SUMME(A:A)/ZÄHLENWENN(A:A;"<>0") sollte doch langen!

=ZÄHLENWENN(A:A;"<>0") zählt korrekt alle Zellen ungleich Null.
Werden Zahlen gelöscht (Taste Entf) verändert sich das Zählresultat nicht ???

Andy:
habe die Formeln getestet-OK
Allerdings:
=ZÄHLENWENN(A:A;"<>0") ist wohl ein Bug.
Die Ergebnisse sind beliebig und nicht nachvollziehbar.
Schon wenn man die Formel runterzieht, gibt sie verschiedene Ergebnisse aus.
Diese Formel darf NICHT verwendet werden!!