Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Datum/Zeit - BEITRAG: Monatsname in Monatszahl und Tagesname in Tageszahl umwandeln*


Aufgabe
Du willst von einem vorgegebenen Monat z.B. "August" die entsprechende Zahl also 8 ermitteln. Oder Du möchtest im entgegengesetzten Fall zu einer Nummer, z.B. 7 den entsprechenden Monat also Juli ermitteln.
Lösung
In A1 steht der ausgeschriebene Monat:

=VERGLEICH(A1;{"Januar";"Februar";"März";"April";"Mai";"Juni";"Juli";"August";"September";"Oktober";"November";"Dezember"};0)
Es handelt sich hierbei um KEINE Array-Formel; - die geschweiften Klammern
mit AltGr7 und AltGr0 {} also eingeben.
oder kürzer:
=SUCHEN(LINKS(A1;3);"WFjanfebmäraprmaijunjulaugsepoktnovdez")/3
weiter eingedampft:
=SUCHEN(TEIL(A1;2;2);"Wanebärpraiunulugepktovez")/2

Das gleiche funktioniert auch mit Wochentagen:
=SUCHEN(LINKS(A1;2);"-modimidofrsaso")/2
oder als Arrayformel:
{=VERGLEICH(A1;TEXT(ZEILE(2:8);"TTTT");0)}


In A1 steht die Zahl
=TEXT(DATUM(1;A1;1);"MMMM")
oder auf englisch:
=TEXT(DATUM(1;A1;1);"[$-409]MMMM")
liefert den Monat ausgeschrieben
Funktioniert für alle Zahlen auch >12. Können nur 1 bis 12 vorkommen langt:
=TEXT(A1*28;"MMMM") bzw. =TEXT(A1*28;"[$-409]MMMM")

Die Wochentagszahl umgewandelt:
=TEXT(A1+1;"TTTT")

Tip von Joseph Gassner:
Die Funktion MONAT kann auch mit Text, also ausgeschriebenen Monaten umgehen. Im ersten Fall langt:
=MONAT(A1&1)
Das gleiche gilt für die Funktion TEXT:
=TEXT("1."&A1;"M")

Die Anzahl der Monatstage liefert:
=31-TAG((A1&1)-TAG(A1&1)+31)

Die Quartalszahl übrigens liefert:
=AUFRUNDEN(MONAT(A1&1)/3;) oder kürzer =MONAT(MONAT(A1&1)&0)