Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Statistik - BEITRAG: Rangliste der häufigsten X Einträge einer Spalte *


Aufgabe
Du willst wissen, welcher Eintrag in einer Spalte am häufigsten vorkommt, und es soll eine Top-Ten-Rangliste erstellt werden.

       A               B               C       
1 a   
2 c   
3 x   
4 b  0,9996  
5 h   
6 z   
7    
8    
9    
10   0,999  
11   1,9989  
12   3,9988  
13   1,9987  
14   3,9986 


Lösung
Suchspalte: A
B1:
=WENN(ZEILE()>ANZAHL(C:C);"";INDEX(A:A;VERGLEICH(KGRÖSSTE(C:C;ZEILE());C:C;0)))
C1:
=WENN(ODER(A1="";ZÄHLENWENN(A2:A$99;A1)>0);"";ZÄHLENWENN(A$1:A1;A1)-ZEILE()/10000)
B1 und C1 bis zum Listenende kopieren.
In Spalte B steht nun die Rangliste.

ohne Hilfsspalte C (Matthias5)
in B2 (B1 bleibt leer) steht:
{=WENN(ANZAHL2(A:A)=SUMME(ZÄHLENWENN(A$1:A$99;B$1:B1));ZEICHEN(160);INDEX(A:A;VERGLEICH(KGRÖSSTE(ZÄHLENWENN(A$1:A$99;A$1:A$99);1+SUMME(ZÄHLENWENN(A$1:A$99;B$1:B1)));WENN(ZÄHLENWENN(B$1:B1;A$1:A$99)=0;ZÄHLENWENN(A$1:A$99;A$1:A$99));0)))}

Ergänzung
Handelt es sich in der Suchspalte um Zahlen, wird es sehr viel kürzer.
In B1 steht 0 (null) - Nullen in Spalte A werden nicht berücksichtigt.
in B2:
{=MODALWERT(WENN(ISTFEHLER(VERGLEICH(A$1:A$99;B$1:B1;0));A$1:A$99))}
oder
{=MODALWERT(WENN(ZÄHLENWENN(B$1:B1;A$1:A$99)=0;A$1:A$99))}
runterkopieren

Tauchen nur noch Solisten auf, erfolgt #NV