Microsoft Excel

Das Portal zum Thema Excel-Formeln

Gruppe: Summenfunktionen

Beitrag: SUMMEWENN für mehrere Suchkriterien (oder-Verknüpfung)

Aufgabe
Aus einer Liste sollen Werte mit SUMMEWENN summiert werden.
Allerdings soll nicht nur nach einem, sondern nach mehreren Suchkriterien gesucht werden.
Beispiel: Es sollen alle Werte der Spalte B aufsummiert werden, die in Spalte A mit den Suchkriterien aus D1:E1 übereinstimmen:

       A               B               C               D               E       
1 y  831    x  y  
2 750       
3 x  782       
4 751       
5 619       
6 x  345       
7 658       
8 691       
9 x  524       
10 y  297       
11          
12 Summe  2779       

Lösung
Suchspalte: A
Betragsspalte: B
Kriterienbereich: D1:E1

{=SUMME(SUMMEWENN(A:A;D1:E1;B:B))}

Die Groß- und Kleinschreibung wird hierbei ignoriert.

Alternative, vorgeschlagen von Günther Oppold:
{=SUMME(WENN(A1:A10=D1:E1;B1:B10))} bzw. {=SUMME((A1:A10=D1:E1)*B1:B10)}
x und y müssen hier in EINER Zeile stehen (in Formel 1 auch untereinander).
Stehen sie in einer Spalte D1:D2 dann:
{=SUMME((A1:A10=MTRANS(D1:D2))*B1:B10)}

Die Alternativen haben den Vorteil, dass sie mit einer weiteren Bedingung kombiniert werden können, z.B.:
{=SUMME(WENN(A1:A10=D1:E1;B1:B10)*(C1:C10="z"))}
bzw. {=SUMME((A1:A10=D1:E1)*(C1:C10="z")*B1:B10)}

stehen die Suchbegriffe nicht in einem Bereich sondern sollen in der Formel direkt verarbeitet werden, dann:
=SUMME(SUMMEWENN(A:A;{"x";"y"};B:B)) - keine Array-Formel!
bzw.
{=SUMME(WENN((A1:A10="x")+(A1:A10="y");B1:B10))}
{=SUMME(((A1:A10="x")+(A1:A10="y"))*B1:B10)}
{=SUMME((A1:A10={"x"."y"})*B1:B10)}

Erläuterung
In den Formeln ohne WENN und MTRANS funktioniert statt SUMME auch SUMMENPRODUKT ohne Abschluß als ARRAY-Formel mit den {geschweiften} Klammern.